從Perl模塊導入有條件編譯的函數

Question

我有一組日誌和調試功能，我想跨多個模塊/對象使用。我希望能夠使用命令行開關全局地打開/關閉它們。

下面的代碼是這樣做的，但是，我希望能夠省略軟件包名稱並將所有內容保存在單個文件中。

更具體地說，我想日誌函數的名稱導入到各模塊，讓他們可以在沒有任何包名資格（類似於C++ use namespace;指令）被調用，我希望能夠啓用/禁用它們全局使用它們的腳本，如下面的示例代碼所示。

這與我詢問的兩個先前問題here和here有關。

另一件事 - 我不認爲我完全理解爲什麼下面的代碼工作。

#! /usr/bin/perl -w 

use strict; 
use Getopt::Long; 

{ 
    package LogFuncs; 

    use threads; 
    use Time::HiRes qw(gettimeofday); 

    # provide tcpdump style time stamp 
    sub _gf_time { 
     my ($seconds, $microseconds) = gettimeofday(); 
     my @time = localtime($seconds); 

     return sprintf("%02d:%02d:%02d.%06ld", 
      $time[2], $time[1], $time[0], $microseconds); 
    } 

    sub logerr; 

    sub compile { 
     my %params = @_; 

     *logerr = $params{do_logging} 
      ? sub { 
       my $msg = shift; 
       warn _gf_time() . " Thread " . threads->tid() . ": $msg\n"; 
      } 
      : sub { }; 
    }    
} 

{ 
    package FooObj; 

    sub new { 
     my $class = shift; 
     bless {}, $class; 
    }; 

    sub foo_work { 
     my $self = shift; 
     # do some foo work 
     LogFuncs::logerr($self); 
    } 
} 

{ 
    package BarObj; 

    sub new { 
     my $class = shift; 
     my $data = { fooObj => FooObj->new() }; 
     bless $data, $class; 
    } 

    sub bar_work { 
     my $self = shift; 
     $self->{fooObj}->foo_work(); 
     LogFuncs::logerr($self); 
    } 
}   

my $do_logging = 0; 

GetOptions(
    "do_logging" => \$do_logging, 
); 

LogFuncs::compile(do_logging => $do_logging); 

my $bar = BarObj->new(); 
LogFuncs::logerr("Created $bar"); 
$bar->bar_work(); 

Answer 1

如果你想保留所有文件在同一個文件中，爲什麼不把logger放在文件範圍內的頂部詞彙。

GetOptions(do_logging => \$do_logging); 

my $logerr = $do_logging ? sub {logging_code_here()} : sub {}; 

$logerr現在可以在同一個文件在該點之後定義的任何包。

但是，它的速度通常較快構建你的日誌調用如下：

my $logerr = sub { logging_code_here() }; 

$logerr->("some string $some_var") if $do_logging; 

你避免子程序調用和字符串參數$ LOGERR並不需要計算，如果日誌記錄是關閉的方式。

您還可以設置日誌記錄級別：

$logerr->("starting loop")  if $do_logging; 

for (@big_array) { 
    $logerr->("processing $_") if $do_logging > 1; 
    ... 
} 

編輯：雖然我不認爲它的最佳實踐，根據您的意見，這裏是你可能尋找（編譯指示）：

use 5.010; 
use warnings; 
use strict; 
BEGIN { # compile time 
    $INC{'log.pm'}++; # block 'require log;' 
    package log; 
    sub is_active {(caller 1)[10]{log}} # test the hints hash 
    sub import { 
     $^H{log} = 1; # set the hints hash for 'log' 
     my $logmsg = (caller).'::logmsg'; # name of caller's sub 
     no strict 'refs'; 
     *$logmsg = sub {print "logging: @_\n" if is_active} # install sub 
      unless *{$logmsg}{CODE}; # unless we did already 
    } 
    sub unimport { 
     $^H{log} = 0; # unset the hints hash 
    } 
} 

package MyPkg; 

use log; 
logmsg 'hello, world!'; 

{ 
    no log; 
    logmsg 'nope, not here'; 
} 

logmsg 'back again'; 

Answer 2

如果你需要修補一些測井方法（或做其他事有條件的開發環境與生產），你可以把代碼放到一個包裝的import()方法和使用參數在use線啓用/禁用它：

# this is in MyLogger.pm: 
package MyLogger; 

use strict; use warnings; 
use Exporter; 

our @EXPORT_OK = qw(logerr); 

sub import 
{ 
    my ($class, $debug) = @_; 

    if ($debug) 
    { 
      # do whatever you need here - patch methods, turn up the log level to "everything", etc 

      # imports logerr method 
      MyLogger->export_to_level(1, 'logger'); 
    } 
} 

sub logerr 
{ 
    # your patched method here.. 
} 

1; 

# (now in your application code...) 
use MyLogger "debug"; # enables debugging mode 
# or: 
use MyLogger MyConfig::DEBUG; # uses a debugging constant that you defined elsewhere 

Answer 3

下面你將你的代碼沒有明確包的日誌記錄功能。我已經將LogFuncs :: compile重命名爲logerr：setup更清晰一些，並且不會污染主命名空間。 perl中的所有東西都有一個包，默認情況下它只是主要。我認爲你之前使用的包含日誌記錄功能的代碼實際上是更清晰的，並且可以很容易地將它分割成單獨的模塊，因此可以更容易地重用它。至於不理解代碼是如何工作的，我不知道如何解決這個問題，但僅僅是因爲你沒有確定任何你不明白的細節。我會假設你是指包裹。 Perl包可以被視爲名稱空間或類。對於LogFuncs軟件包，您將其用作命名空間，並且在其中創建的潛水艇將作爲靜態類方法進行訪問（以使用其他更傳統的面向對象的傳統OO語言的某些表示法）。包FooObj和BarObj通過提供構造函數new（）更傳統上用作對象，並期望使用對象表示法（ - > sub）調用其中的子對象，自動將對象本身作爲第一個參數傳遞給子對象/方法。將sub定義爲靜態類方法或對象方法的唯一方法是是否期望接收該對象作爲第一個參數。因此，通過正確地確定第一個傳遞的參數是什麼並且相應地執行，一些小心的預見和仔細的編程可以生成對兩者都有效的子程序。

#! /usr/bin/perl -w 

use strict; 
use Getopt::Long; 

use threads; 
use Time::HiRes qw(gettimeofday); 

# provide tcpdump style time stamp 
sub _gf_time { 
my ($seconds, $microseconds) = gettimeofday(); 
my @time = localtime($seconds); 

return sprintf("%02d:%02d:%02d.%06ld", 
    $time[2], $time[1], $time[0], $microseconds); 
} 

sub logerr; 

sub logerr_setup { 
    my %params = @_; 

    *logerr = $params{do_logging} 
     ? sub { 
      my $msg = shift; 
      warn _gf_time() . " Thread " . threads->tid() . ": $msg\n"; 
     } 
     : sub { }; 
    } 

{ 
    package FooObj; 

    sub new { 
     my $class = shift; 
     bless {}, $class; 
    }; 

    sub foo_work { 
     my $self = shift; 
     # do some foo work 
     main::logerr($self); 
    } 
} 

{ 
    package BarObj; 

    sub new { 
     my $class = shift; 
     my $data = { fooObj => FooObj->new() }; 
     bless $data, $class; 
    } 

    sub bar_work { 
     my $self = shift; 
     $self->{fooObj}->foo_work(); 
     main::logerr($self); 
    } 
} 

my $do_logging = 0; 

GetOptions(
    "do_logging" => \$do_logging, 
); 

logerr_setup(do_logging => $do_logging); 

my $bar = BarObj->new(); 
logerr("Created $bar"); 
$bar->bar_work();