XSLT計數逗號值計數

Question

我在xml中有一個像integer =「1,2,3,4,5」的值。如何計算使用XSLT的總數。從而使輸出給了我5個

問候計數， 山姆

Answer 1

這裏有一種方法（可能還有其他）。簡單地翻譯所有逗號爲空字符串，然後在差異比較字符串的長度：

<xsl:value-of 
    select="string-length(@integer) 
      - string-length(translate(@integer, ',', '')) + 1" /> 

如果您需要處理空字符串，試試這個，而不是

<xsl:value-of 
    select="string-length(@integer) 
      - string-length(translate(@integer, ',', '')) 
      + 1 * (string-length(@integer) != 0)" /> 

Answer 2

如果要算上逗號 - 分隔值，但也可以引用單個項目，您可以使用像這樣的遞歸模板。

這XSLT 1.0樣式表將逗號分隔值轉換爲節點，然後計算它們...

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"> 
<xsl:output method="text"/> 

<xsl:template match="/"> 
<xsl:variable name="as-nodes"> 
    <xsl:call-template name="parse-comma-separated-values"> 
    <xsl:with-param name="csv" select="t/@csv" /> 
    </xsl:call-template> 
    </xsl:variable> 
    <xsl:value-of select="count(msxsl:node-set($as-nodes)/*)" /> 
</xsl:template> 

<xsl:template name="parse-comma-separated-values"> 
<xsl:param name="csv" /> 
<xsl:choose> 
    <xsl:when test="$csv = ''"/> 
    <xsl:when test="not(contains($csv, ','))"> 
    <value-node value="{$csv}" /> 
    </xsl:when> 
    <xsl:otherwise> 
    <value-node value="{substring-before($csv,',')}" /> 
    <xsl:call-template name="parse-comma-separated-values"> 
     <xsl:with-param name="csv" select="substring-after($csv,',')"/> 
    </xsl:call-template> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:template> 

</xsl:stylesheet> 

...當施加到該輸入文件...

<t csv="1,2,3,4,5"/> 

... ...產生

5