如何解析在XSLT查詢參數

Question

我有一個要求，我會得到URL在這樣的格式如下 https://sample.com?first=one&second=two&third=three

我怎樣才能形成以下將通過使用此查詢參數形成XML結構

<first>one</first><second>two</second><third>three</third> 

可以請別人幫我thisand給我提供的XSLT這一要求

Answer 1

鑑於以下XML輸入（注意轉義符號字符的）：

<URL>https://sample.com?first=one&amp;second=two&amp;third=three</URL> 

如下因素的樣式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:template match="/"> 
    <output> 
     <xsl:call-template name="tokenize"> 
      <xsl:with-param name="text" select="substring-after(URL, '?')"/> 
     </xsl:call-template> 
    </output> 
</xsl:template> 

<xsl:template name="tokenize"> 
    <xsl:param name="text"/> 
    <xsl:param name="delimiter" select="'&amp;'"/> 
     <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" /> 
     <xsl:if test="$token"> 
      <xsl:element name="{substring-before($token, '=')}"> 
       <xsl:value-of select="substring-after($token, '=')"/> 
      </xsl:element> 
     </xsl:if> 
     <xsl:if test="contains($text, $delimiter)"> 
      <!-- recursive call --> 
      <xsl:call-template name="tokenize"> 
       <xsl:with-param name="text" select="substring-after($text, $delimiter)"/> 
      </xsl:call-template> 
     </xsl:if> 
</xsl:template> 

</xsl:stylesheet> 

將返回：

<?xml version="1.0" encoding="UTF-8"?> 
<output> 
    <first>one</first> 
    <second>two</second> 
    <third>three</third> 
</output> 

請注意，這隻有在工作查詢字段名稱也是有效的XML元素名稱。