XSLT1，Muenchian分組的，列出了分組節點在foreach循環

Question

由於XML代碼

<z> 
<f hit="1"> 
<g>hola1</g> 
</f> 
<f hit="2"> 
<g>hola2</g> 
</f> 
<f hit="3"> 
<g>hola1</g> 
</f> 
</z> 

我想用xslt1有XML輸出

<z> 
hola1 
hola2 
</z> 

。然後，一個簡單的解決辦法是Muenchian分組的

<xsl:key name="thisone" match="/z/f/g" use="." /> 
<z> 
<xsl:for-each select="/z/f[generate-id(g)=generate-id(key('thisone',g)[1])]"> 
<xsl:value-of select="g" /> 
</xsl:for-each> 
</z> 

但是，我申請這一個大的數據集時，系統（火狐）一直想永遠。我認爲這是由於真的很大的數據集。但是，「g」的不同值的數量真的很低。

我的問題是：有沒有辦法做Muenchian分組的的節點for-each循環？像

<xsl:for-each select="nodes_of_key('thisone')"> 

這將避免比較所有的「g」節點的所有值，這將永遠需要？

感謝

Answer 1

一個並不需要任何<xsl:for-each>指令來解決這個問題（這個指令，最好避免）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="kFByG" match="f" use="g"/> 

<xsl:template match="/*"> 
    <z> 
     <xsl:apply-templates/> 
     <xsl:text>&#xA;</xsl:text> 
    </z> 
</xsl:template> 

<xsl:template match="f[generate-id()=generate-id(key('kFByG',g)[1])]"> 
    <xsl:text>&#xA;</xsl:text> 
    <xsl:value-of select="g"/> 
</xsl:template> 
<xsl:template match="text()"/> 
</xsl:stylesheet> 

當這種變換所提供的XML文檔應用：

<z> 
    <f hit="1"> 
     <g>hola1</g> 
    </f> 
    <f hit="2"> 
     <g>hola2</g> 
    </f> 
    <f hit="3"> 
     <g>hola1</g> 
    </f> 
</z> 

想要的，正確的結果產生：

<z> 
hola1 
hola2 
</z>