將多個數據放在一個單元格中ASP.NET，VB.NET

Question

如何將多個數據放在一個數據網格單元格中？例如，用戶可以是不同組織的成員。

但我不希望表爲同一個用戶創建一個新的DataGrid行，這是多個組織的成員。

這是怎樣的代碼看起來像現在：

Dim dSourceMemberOf As New SqlDataAdapter("QUERY", dbConn) 

這充滿DataGrid中，但對於一些用戶有更多然後5行。所以我想把一個特定的列放在一個單元格中的所有數據。

這怎麼辦？

編輯：

這是怎麼woud看起來像現在：

username memberof 
user1  dft 
user1  kbo 
user2  test 

而且這是我希望它looke像：

username memberof 
user1  dft 
      kbo 
user2  test 

Answer 1

我認爲最好的解決方案是使用Linq查詢對數據進行分組，然後分組數據綁定到一個GridView：

所以在GridView是這樣的：

<asp:GridView ID="GridView1" runat="server" AutoGenerateColumns="False"> 
    <Columns> 
     <asp:BoundField DataField="UserName" /> 
     <asp:TemplateField> 
      <ItemTemplate> 
       <asp:ListBox ID="lst" runat="server" DataSource="<%# Container.DataItem.MemberOfGrouped %>" DataTextField="MemberOf"></asp:ListBox> 
      </ItemTemplate> 

     </asp:TemplateField> 
    </Columns> 
</asp:GridView> 

，這裏是一些示例代碼來填充它：

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load 

    Dim UngroupedData As List(Of YourData) = New List(Of YourData)() 
    Dim item1 As YourData = New YourData() 
    item1.MemberOf = "dft" 
    item1.UserName = "user1" 
    UngroupedData.Add(item1) 

    Dim item2 As YourData = New YourData() 
    item2.MemberOf = "kbo" 
    item2.UserName = "user1" 
    UngroupedData.Add(item2) 

    Dim grouped = From u In UngroupedData Group u By Key = u.UserName Into Group _ 
        Select UserName = Key, MemberOfGrouped = Group.ToList() 


    GridView1.DataSource = grouped 
    GridView1.DataBind() 
End Sub 


Public Class YourData 

    Private _userName As String 
    Public Property UserName() As String 
     Get 
      Return _userName 
     End Get 
     Set(ByVal value As String) 
      _userName = value 
     End Set 
    End Property 


    Private _memberOf As String 
    Public Property MemberOf() As String 
     Get 
      Return _memberOf 
     End Get 
     Set(ByVal value As String) 
      _memberOf = value 
     End Set 
    End Property 
End Class 

Answer 2

對不起，我覺得油漆錯了，概念是正確的 - 看起來你需要在databind event活動上做... more here（前三個鏈接會告訴你如何做你所需要的，我認爲） - you co你看上一行，得到上一行，然後根據上一行決定如何處理當前行中的單元格

Answer 3

你可以在使用能夠在GridView-Cell（或Ross Scott建議的列表框）中使用。

<ItemTemplate> 
    <asp:table id="TblUserGroups" runat="server" Height="100%" Width="100%" CellSpacing="0" CellPadding="0"> 
    </asp:table> 
</ItemTemplate> 

和GridView控件中的RowDataBound（數據網格的ItemDataBound的工作原理類似）：

Protected Sub Gridview1_RowDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.GridViewRowEventArgs) Handles Gridview1.RowDataBound 
    Select Case e.Row.RowType 
     Case DataControlRowType.DataRow 
      Dim drUser As DataRowView = DirectCast(e.Row.DataItem, DataRowView) 
      Dim TblUserGroups As Table = DirectCast(e.Row.FindControl("TblUserGroups"), Table) 
      Dim userID as int32 = Ctype(drUser(0), Int32) 
      Dim tblGroups as DataTable = getTblUserGroups(userID) 'write a function that returns the Groups of a given User f.e. as DataTable' 
      If tblGroups.Rows.Count = 0 Then 
       Dim tr As New TableRow 
       Dim td As New TableCell 
       Dim LblNoGroup As New Label 
       LblNoGroup .Text = "no user-group" 
       td.CssClass = "UserWithoutGroup" 
       td.Controls.Add(LblNoGroup) 
       tr.Cells.Add(td) 
       TblUserGroups.Rows.Add(tr) 
      Else 
       For Each groupRow As DataRow In tblGroups.Rows 
        Dim tr As New TableRow 
        Dim td As New TableCell 
        Dim LblGroup As New Label 
        LblGroup.Text = groupRow("GroupName").ToString 'The groups name column' 
        td.Controls.Add(LblGroup) 
        tr.Cells.Add(td) 
        TblUserGroups.Rows.Add(tr) 
       Next 
      End If 
    End Select 
End Sub 

我覺得這是最靈活的方式。