我想使用XSLT

Question

我想下面的XML文件輸出增加 「的xmlns」 屬性的XML文件：

<?xml version="1.0" encoding="ISO-8859-1" ?> 
- <T0020 xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.safersys.org/namespaces/T0020V1"> 
- <INTERFACE> 
    <NAME>SAFER</NAME> 
    <VERSION>04.02</VERSION> 
    </INTERFACE> 

對於我有以下XSLT文件：

<xsl:template match="T0020" > 
    <xsl:copy> 
    <xsl:attribute name="xsi:schemaLocation" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd </xsl:attribute> 

    //some code here...............// 

<xsl:copy> 

所以我在<T0020>標籤下添加xmlns =「http://www.safersys.org/namespaces/T0020V1」屬性

Answer 1

該樣式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="*"> 
     <xsl:element name="{name()}" namespace="http://www.safersys.org/namespaces/T0020V1"> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:element> 
    </xsl:template> 
    <xsl:template match="T0020"> 
     <xsl:element name="{name()}" namespace="http://www.safersys.org/namespaces/T0020V1"> 
      <xsl:attribute name="xsi:schemaLocation">http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd</xsl:attribute> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

利用該輸入：

<T0020> 
    <INTERFACE> 
     <NAME>SAFER</NAME> 
     <VERSION>04.02</VERSION> 
    </INTERFACE> 
</T0020> 

輸出：

<T0020 xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.safersys.org/namespaces/T0020V1"> 
    <INTERFACE> 
     <NAME>SAFER</NAME> 
     <VERSION>04.02</VERSION> 
    </INTERFACE> 
</T0020> 

注：命名空間節點不是屬性節點。如果你想讓沒有命名空間的元素在某個命名空間下得到輸出，你需要xsl:element/@namespace。

Answer 2

這種轉變：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:variable name="vDefaultNS" 
    select="'http://www.safersys.org/namespaces/T0020V1'"/> 

<xsl:template match="*"> 
    <xsl:element name="{name()}" namespace="{$vDefaultNS}"> 
    <xsl:copy-of select="namespace::* | @*"/> 
    <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

當這個XML文檔施加：

<T0020 xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd" 
> 
<INTERFACE> 
    <NAME>SAFER</NAME> 
    <VERSION>04.02</VERSION> 
</INTERFACE> 
</T0020> 

產生通緝的結果：

<T0020 xmlns="http://www.safersys.org/namespaces/T0020V1" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.safersys.org/namespaces/T0020V1 T0020V1.xsd"> 
    <INTERFACE> 
     <NAME>SAFER</NAME> 
     <VERSION>04.02</VERSION> 
    </INTERFACE> 
</T0020> 

請注意xmlns不是一個屬性，但表示一個名稱空間聲明。