有沒有一種簡潔的方式來更新記錄的TDictionary中的所有值？

Question

我想要做這樣的事情，但它不會編譯，因爲Pair不能分配給。

var 
    MyDictionary: TDictionary<TGuid, TCustomRecord>; 
    Pair: TPair<TGuid, TCustomRecord>; 
begin 
    // ... create and populate my dictionary ... 

    foreach Pair in MyDictionary do 
    begin 
    PairRef.Value.MyField := PairRef.Value.MyField + 1; 
    end; 
end 

只是要清楚，我知道如何用更多的代碼來實現這一點，我在尋找簡潔易讀的東西。

Answer 1

TDictionary上沒有迭代器，它返回對值的引用。所有的迭代器都提供了值，這意味着你所要求的是當前設計所不可能的。

在其他語言中，例如我知道的C++和D，引用是該語言中的第一類公民。您可以輕鬆地編寫枚舉引用而不是值的迭代器。這就是你需要簡潔地解決你的問題。不幸的是，這種語言缺乏。

一個明顯的選擇是切換到使用引用類型（類）而不是值類型（記錄）。這將解決中風中的迭代問題，因爲它將迭代引用。然而，人們通常選擇使用價值類型是有原因的，而且您可能會遇到阻礙您進行此類轉換的限制。

另一種可能性是編寫一個容器，該容器提供了提供指向值的指針的迭代器。這與您可以獲得對記錄的引用盡可能接近。但是你將不得不推出自己的容器。

Answer 2

下面是一個簡單的程序，它顯示了使用記錄和對象與TDictionary不同的處理。

program Project1; 

{$APPTYPE CONSOLE} 
{$R *.res} 

uses 
    System.SysUtils, System.Generics.Collections; 

type 
    TMyRecord = record 
    Field : Integer; 
    end; 

    TMyObject = class 
    Field : Integer; 
    end; 

procedure UseObjectDict; 
var 
    LDict : TDictionary<TGUID, TMyObject>; 
    LValue : TMyObject; 
begin 
    write('TMyObject: '); 

    LDict := TObjectDictionary<TGUID, TMyObject>.Create([doOwnsValues]); 
    try 

    // populate 
    while LDict.Count < 10 do 
    begin 
     LDict.Add(TGuid.NewGuid, TMyObject.Create); 
    end; 

    // update 
    for LValue in LDict.Values do 
     begin 
     LValue.Field := LValue.Field + 1; 
     end; 

    // output 
    for LValue in LDict.Values do 
     begin 
     write(LValue.Field, ', '); 
     end; 
    Writeln; 

    finally 
    LDict.Free; 
    end; 
end; 

procedure UseRecordDict; 
var 
    LDict : TDictionary<TGUID, TMyRecord>; 
    LKey : TGUID; 
    LValue : TMyRecord; 
begin 
    write('TMyRecord: '); 
    LDict := TDictionary<TGUID, TMyRecord>.Create; 
    try 

    // populate 
    while LDict.Count < 10 do 
     begin 
     LValue.Field := 0; 
     LDict.Add(TGuid.NewGuid, LValue); 
     end; 

    // update 
    for LKey in LDict.Keys do 
     begin 
     LValue.Field := LDict[LKey].Field + 1; 
     LDict.AddOrSetValue(LKey, LValue); 
     end; 

    // output 
    for LValue in LDict.Values do 
     begin 
     write(LValue.Field, ', '); 
     end; 
    Writeln; 

    finally 
    LDict.Free; 
    end; 
end; 

begin 
    ReportMemoryLeaksOnShutdown := True; 
    try 

    UseObjectDict; 
    UseRecordDict; 

    except 
    on E : Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 

    ReadLn; 

end.