排序補丁集或agentset用的NetLogo

Question

兩個條件

我的補丁有cost和gain屬性，我想用最小的cost和最大gain排序補丁列表。 sort-by函數用於對一個屬性進行排序，但我如何排序這兩個屬性？

Answer 1

排序許多屬性的agentset，您可以使用sort-by或sort-on：你更喜歡哪一個

patches-own [ cost gain ] 

to sort-patches 
    ca 
    ask patches [ 
    set cost random 100 
    set gain random 100 
    ] 

    let patches-sorted-by sort-by [ 
    ([ cost ] of ?1 > [ cost ] of ?2) or 
    ([ cost ] of ?1 = [ cost ] of ?2 and [ gain ] of ?1 < [ gain ] of ?2) 
    ] patches 
    show map [[ list cost gain ] of ? ] patches-sorted-by 

    let patches-sorted-on sort-on [ (cost * -1000) + gain ] patches 
    show map [[ list cost gain ] of ? ] patches-sorted-on 
end 

是你。使用sort-on需要仔細構建公式（即，如果您可以獲得大於1000的收益，則以上方法將不起作用），但稍微不詳細。

編輯：多項標準

確定排序的更一般的方式，這可能是您的情況矯枉過正，但我​​想出了很多更一般的：

to-report sort-by-criteria [ criteria items ] 
    ; `criteria` needs to be a task that returns a list of numbers 
    report sort-by [ 
    compare-lists (runresult criteria ?1) (runresult criteria ?2) 
    ] items 
end 

to-report compare-lists [ l1 l2 ] 
    report ifelse-value (empty? l1 or empty? l2) [ false ] [ 
    ifelse-value (first l1 = first l2) 
     [ compare-lists but-first l1 but-first l2 ] 
     [ first l1 < first l2 ] 
    ] 
end 

什麼你需要通過sort-by-criteria是一個task，給定你想要排序的項目之一，將報告一個數字列表，根據該列表你的項目將被排序。

在你的情況，你會使用它想：

let sorted-patches sort-by-criteria (
    task [[ list (-1 * cost) gain ] of ? ] 
) patches 

對於兩個標準，它可能不值得使用，但如果你有標準的長列表，它很可能是一個更容易和更清晰使用比其他任何方法。