如何在xml中提取xml在Oracle中

Question

我試圖從xmltype文檔中提取xml。

DECLARE 
    xmlData   XMLType; 
    sDocumentId  VARCHAR2(100); 
    sFormat   VARCHAR2(100); 
    cData   CLOB; 
BEGIN 
    xmlData := XMLType('<main> 
         <document_id>1234567</document_id> 
         <format>E66</format> 
         <data><Fname>ABCD</Fname><Lname>EFGD</Lname></data> 
        </main>'); 

    SELECT ExtractValue(xmlData, '/main/document_id/text()'), 
     ExtractValue(xmlData, '/main/format/text()'), 
     ExtractValue(xmlData, '/main/data/text()') 
    INTO sDocumentId, 
     sFormat, 
     cData 
    FROM (SELECT xmlData FROM DUAL); 

    dbms_output.put_line(sDocumentId); 
    dbms_output.put_line(sFormat); 
    dbms_output.put_line(cData); 
END; 

如何得到的輸出是這樣的：

• DocumentId = 1234567
• sFormat = E66
• CDATA = <Fname>ABCD</Fname><Lname>EFGD</Lname>

Answer 1

你可以這樣說：

SELECT EXTRACTVALUE(xmlData, '/main/document_id/text()'), 
    EXTRACTVALUE(xmlData, '/main/format/text()'), 
    EXTRACT(xmlData, '/main/data').GetClobVal() 
INTO sDocumentId, 
    sFormat, 
    cData 
FROM (SELECT xmlData FROM DUAL) t; 

請注意，EXTRACTVALUE和EXTRACT已被棄用。但是，我沒使用XMLTABLE，但是這可能是一個起點：

SELECT * 
INTO sDocumentId, 
    sFormat, 
    cData 
FROM XMLTABLE('/main' PASSING xmlData COLUMNS 
    sDocumentId VARCHAR2(100) PATH 'document_id/text()', 
    sFormat VARCHAR2(100) PATH 'format/text()', 
    cData VARCHAR2(1000) PATH 'data/text()'); 

Answer 2

使用下面的代碼。

DECLARE 
xmlData   XMLType; 
sDocumentId  VARCHAR2(100); 
sFormat   VARCHAR2(100); 
cData   Clob; 

BEGIN 

xmlData := XMLType('<main> 
       <document_id>1234567</document_id> 
       <format>E66</format> 
       <data><Fname>ABCD</Fname><Lname>EFGD</Lname></data> 
      </main>'); 


SELECT ExtractValue(xmlData, '/main/document_id/text()'), 
     ExtractValue(xmlData, '/main/format/text()'), 
     EXTRACT(xmlData,'/main/data').getClobVal() 
INTO sDocumentId, 
     sFormat, 
     cData 
FROM (SELECT xmlData FROM DUAL); 


dbms_output.put_line(sDocumentId); 
dbms_output.put_line(sFormat); 
dbms_output.put_line(cData); 

END; 

輸出將被

1234567 
E66 
<data><Fname>ABCD</Fname><Lname>EFGD</Lname></data>