在使用XSLT轉換XML時保留實體引用？

Question

如何在使用XSLT（2.0）轉換XML時保留實體引用？在我嘗試過的所有處理器中，默認情況下都會解析實體。我可以使用xsl:character-map來處理字符實體，但是文本實體呢？

例如，該XML：

<!DOCTYPE doc [ 
<!ENTITY so "stackoverflow"> 
<!ENTITY question "How can I preserve the entity reference when transforming with XSLT??"> 
]> 
<doc> 
    <text>Hello &so;!</text> 
    <text>&question;</text> 
</doc> 

與下面的XSLT變換：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

產生以下輸出：

<doc> 
    <text>Hello stackoverflow!</text> 
    <text>How can I preserve the entity reference when transforming with XSLT??</text> 
</doc> 

輸出應看起來像輸入（減去現在的文檔類型聲明）：

<doc> 
    <text>Hello &so;!</text> 
    <text>&question;</text> 
</doc> 

我希望，我沒有更換所有＆符號與&替換所有&預先處理的輸入與&（如&question;），然後處理後的輸出。

也許這是處理器特定的？我正在使用撒克遜9.

謝謝！

Answer 1

如果你知道的實體將被用於什麼，他們是如何定義的，你可以做以下（相當原始，而且容易出錯，但仍比沒有好）：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:my="my:my"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:character-map name="mapEntities"> 
    <xsl:output-character character="&amp;" string="&amp;"/> 
</xsl:character-map> 

<xsl:variable name="vEntities" select= 
"'stackoverflow', 
'How can I preserve the entity reference when transforming with XSLT\?\?' 
"/> 

<xsl:variable name="vReplacements" select= 
"'&amp;so;', '&amp;question;'"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:text disable-output-escaping="yes"><![CDATA[<!DOCTYPE doc [ <!ENTITY so "stackoverflow"> 
<!ENTITY question 
"How can I preserve the entity reference when transforming with XSLT??"> ]> 
]]> 
    </xsl:text> 

    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="text()"> 
    <xsl:value-of select= 
    "my:multiReplace(., 
        $vEntities, 
        $vReplacements, 
        count($vEntities) 
        ) 
    " disable-output-escaping="yes"/> 
</xsl:template> 

<xsl:function name="my:multiReplace"> 
    <xsl:param name="pText" as="xs:string"/> 
    <xsl:param name="pEnts" as="xs:string*"/> 
    <xsl:param name="pReps" as="xs:string*"/> 
    <xsl:param name="pCount" as="xs:integer"/> 

    <xsl:sequence select= 
    "if($pCount > 0) 
    then 
     my:multiReplace(replace($pText, 
           $pEnts[1], 
           $pReps[1] 
          ), 
         subsequence($pEnts,2), 
         subsequence($pReps,2), 
         $pCount -1 
        ) 
     else 
     $pText 
    "/> 
</xsl:function> 
</xsl:stylesheet> 

應用時所提供的XML文檔：

<!DOCTYPE doc [ <!ENTITY so "stackoverflow"> 
<!ENTITY question 
"How can I preserve the entity reference when transforming with XSLT??"> ]> 
<doc> 
    <text>Hello &so;!</text> 
    <text>&question;</text> 
</doc> 

有用結果產生：

<!DOCTYPE doc [ <!ENTITY so "stackoverflow"> 
<!ENTITY question 
"How can I preserve the entity reference when transforming with XSLT??"> ]> 

    <doc> 
     <text>Hello &so;!</text> 
     <text>&question;</text> 
</doc> 

請注意：

1. 在替代的特殊（正則表達式）字符必須轉義。

2. 我們需要解決DOE，這是不推薦的，因爲它違反了XSLT架構和處理模型的原則 - 換句話說，這個解決方案是一個討厭的黑客。

Answer 2

如果您使用的是Java實現的XSLT 2.0處理器（如撒克遜9的Java），你可能要檢查http://andrewjwelch.com/lexev/是否幫助了，你可以用，讓他們打上這樣的實體和字符引用進行預處理的XML作爲XML元素，您可以根據需要進行轉換。

Answer 3

如果您使用類似S1000D的東西，這可能是一個特別麻煩的問題。它使用實體和@boardno屬性鏈接到數字。這是它的SGML根源的倒退。

由於這種自動實體擴展行爲正確但不可取，因此在使用S1000D作爲輸入時，我經常需要退回到像sed，awk和批處理腳本這樣的工具來管理某些數據分析任務。對於即將到來的XSLT規範之一，這將是一個很好的變更建議，即兼容的處理器接受一個可以打開和關閉entitiy擴展的運行時參數。

Answer 4

通過使用「實體」參數設置爲true的DOM LS分析器，可以將EntityReference節點保留在文檔中。 http://docs.oracle.com/javase/6/docs/api/org/w3c/dom/DOMConfiguration.html

該規範說默認值是true，但取決於解析器，它可能是錯誤的，請注意這一點。

要加載的Xerces：

DOMImplementationLS domImpl = new org.apache.xerces.dom.CoreDOMImplementationImpl(); 

您可以使用註冊表如下太多，但personnaly，我寧願寫死我如上要實現：

DOMImplementationRegistry registry = DOMImplementationRegistry.newInstance(); 
DOMImplementationLS domImpl = (DOMImplementationLS) registry.getDOMImplementation("XML 3.0 LS 3.0"); 

然後，裝入您的文檔：

// XML parser with XSD schema 
LSParser parser = domImpl.createLSParser(DOMImplementationLS.MODE_SYNCHRONOUS, "http://www.w3.org/2001/XMLSchema"); 
DOMConfiguration config = parser.getDomConfig(); 
config.setParameter("entities", true); 
LSInput input = impl.createLSInput(); 
Document lDoc = parser.parse(your XML stream); 

然後，您的XML實體不在DOM中展開。 ，你不能使用net.sf.saxon.xpath.XPathFactoryImpl，你必須設置的Xerces默認的XPathFactory與XPathFactory.newInstance（）

然後，因爲SAXON不處理的實體不擴大（錯誤「在DOM！5不支持節點類型」）

Answer 5

我使用這個解決方案，它運作良好：

<xsl:variable name="prolog" select="substring-before(unparsed-text(document-uri(.)),'&lt;root')"/> 

<xsl:template match="/"> 
    <xsl:value-of select="$prolog" disable-output-escaping="yes"/> 
    <xsl:apply-templates/> 
</xsl:template>