轉換字符串 「abc」，以$哈希 - > {A} - > {B} - > {C}在Perl

Question

我有動態嵌套哈希裁判是這樣的：

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

我想設置通過允許用戶輸入「abc something」，將c的值賦予「something」。

現在越來越值可以做這樣的：

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

但我怎麼會設置的關鍵c價值$v，使

print Dumper $hash; 

將反映變化？ $h不是foreach循環結尾的ref，因此更改不會反映$hash中的更改。任何提示如何解決我腦海中的結嗎？

Answer 1

事情是這樣的：

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

飛出最後的關鍵是wusses！ ;）

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

此功能更強大（因此稍微難以使用）版本由Data::Diver提供。

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

（daxim的使用稍微偏離。）