如何將某些命令的輸出重定向到文件，但將某些命令保留在控制檯中？

Question

我使用下面的perl腳本，

open (STDOUT, '>',"log.txt")|| die "ERROR: opening log.txt\n"; 
print "\n inside"; 
close (STDOUT); 
print "\noutside"; 

我需要字符串「內部」需要內部log.txt中進行打印。需要在控制檯中打印「外部」字符串。

但是用我的腳本字符串「inside」打印在log.txt中，但字符串「outside」不打印在控制檯上。

任何人都可以幫助我在此

Answer 1

您redirect the standard output stream到一個文件open STDOUT, '>', $file。之後，沒有簡單的方法可以打印到控制檯。

一些方法來打印到既文件和控制檯

• 保存STDOUT重定向之前，並恢復它在需要時以後。再次，看open

  open SAVEOUT, ">&STDOUT" or warn "Can't dup STDOUT: $!"; 
  open *STDOUT, ">", $logfile or warn "Can't redirect STDOUT to $logfile: $!"; 
  say "goes to file"; 
  ... 
  open STDOUT, ">&SAVEOUT" or warn "Can't reopen STDOUT: $!"; # restore 
  say "goes to console"; 
  

• 打印到一個變量，你打算控制檯什麼;使用select切換的地方印刷品去

  open my $fh_so, '>', \my $for_stdout; 
  select $fh_so; 
  say "goes to variable \$for_stdout"; 
  say STDOUT "goes to console"; 
  ... 
  select STDOUT; # make STDOUT default again 
  say $for_stdout; # goes to console (all accumulated $fh_so prints) 
  

  有了這個，你可以通過指定STDOUT到達控制檯中的默認，否則你會拿出所有標準輸出，打算打印一旦你select回STDOUT

• 打印日誌直接文件，如在Jens's answer

  open my $fh_log, '>', $logfile or die "Can't open $logfile: $!"; 
  say $fh_log "goes to $logfile"; 
  say   "goes to console"; 
  ... 
  close $fh_log; 
  

  其中默認print（或更確切地說say）繼續去控制檯

前兩個看起來有點麻煩，不是他們。我建議直接將日誌打印到日誌文件中，除非需要爲大部分程序重定向STDOUT，或者您有一個令人信服的理由來處理文件句柄。

對於say，它爲打印的內容添加換行符，您需要在開始處使用use feature 'say';。請致電use warnings;和use strict;。