建立一個散列表gensym和宏小號

Question

我想建立一個散列表（除其他動作），而read ing。我不希望哈希表具有全局範圍（但），所以我用宏和gensym來做這件事。在宏x內部，我正在定義一個類似於setf的宏s，但在散列表中定義了一個條目而不是在某處定義了一個符號。它爆炸了。我想我理解錯誤信息，但是如何使其工作？

代碼：

#!/usr/bin/clisp -repl 

(defmacro x (&rest statements) 
    (let ((config-variables (gensym))) 
    `(macrolet ((s (place value) 
        (setf (gethash 'place ,config-variables) value))) 
     (let ((,config-variables (make-hash-table :test #'eq))) 
     (progn ,@statements) 
     ,config-variables)))) 

(defun load-config() 
    (let ((config-file-tree (read *standard-input*))) 
    (eval config-file-tree))) 

(defun load-test-config() 
    (with-input-from-string (*standard-input* "(x (s fred 3) (s barney 5))") 
    (load-config))) 

(load-test-config) 

輸出：

*** - LET*: variable #:G12655 has no value 
The following restarts are available: 
USE-VALUE  :R1  Input a value to be used instead of #:G12655. 
STORE-VALUE :R2  Input a new value for #:G12655. 
SKIP   :R3  skip (LOAD-TEST-CONFIG) 
STOP   :R4  stop loading file /u/asterisk/semicolon/build.l/stackoverflow-semi 

Answer 1

在macrolet你也定義一個宏，所以通常的規則適用，即你必須反引號的表達式，這是在運行時進行評估。像這樣：

(defmacro x (&rest statements) 
    (let ((config-variables (gensym))) 
    `(macrolet ((s (place value) 
       `(setf (gethash ',place ,',config-variables) ,value))) 
     (let ((,config-variables (make-hash-table :test #'eq))) 
     (progn ,@statements) 
     ,config-variables)))) 

Answer 2

只是猜測Bill可能真的想要什麼。

假設他想要將某些鍵映射爲某些值作爲文件中的配置。

這是程序方式。

• 打開一個流的數據
• 讀它作爲s表達式
• 走數據和填充的哈希表

示例代碼：

(defun read-mapping (&optional (stream *standard-input*)) 
    (destructuring-bind (type &rest mappings) (read stream) 
    (assert (eq type 'mapping)) 
    (let ((table (make-hash-table))) 
     (loop for (key value) in mappings 
      do (setf (gethash key table) value)) 
     table))) 

(defun load-config() 
    (read-mapping)) 

(defun load-test-config() 
    (with-input-from-string (*standard-input* "(mapping (fred 3) (barney 5))") 
    (load-config))) 

(load-test-config) 

用途：

CL-USER 57 > (load-test-config) 
#<EQL Hash Table{2} 402000151B> 

CL-USER 58 > (describe *) 

#<EQL Hash Table{2} 402000151B> is a HASH-TABLE 
BARNEY  5 
FRED  3 

個

優點：

• 沒有宏
• 數據沒有在源代碼中獲得編碼並通過EVAL生成的源代碼
• 沒有評價（！安全）通過宏需要
• 沒有對象代碼膨脹，其正在擴大到更大代碼
• 功能抽象
• 更容易理解和調試

或者我會寫{的讀取宏，這樣{(fred 3) (barney 5)}將被直接讀爲哈希表。

---

如果你想擁有的計算值：

(defun make-table (mappings &aux (table (make-hash-table))) 
    (loop for (key value) in mappings 
     do (setf (gethash key table) (eval value))) 
    table) 

CL-USER 66> (describe (make-table '((fred (- 10 7)) (barney (- 10 5))))) 

#<EQL Hash Table{2} 4020000A4B> is a HASH-TABLE 
BARNEY  5 
FRED  3 

談到的是成宏：

(defmacro defmapping (&body mappings) 
    `(make-table ',mappings)) 

(defmapping 
    (fred 3) 
    (barney 5))