如何獲取VBA中的列名？

我已經創建了一個模塊，使用存儲過程從SQL數據庫中讀取數據，並且獲取所有必需的數據，但是我的要求是我也需要所有列名稱/標題。而且我無法對名稱進行硬編碼，因爲我正在將數據行轉換爲存儲過程中的列。如何獲取VBA中的列名？

這是我寫的代碼：

ConnStr = "PROVIDER=SQLOLEDB.1;" 
ConnStr = ConnStr & "DATA SOURCE=" & dataSrc & "; INITIAL CATALOG=" & iCatalog & "; " 
ConnStr = ConnStr & "User ID = " & dbUserId & "; Password = " & dbPassword 

On Error GoTo ErrHandler 

DBConn.Open ConnStr 

' Create a recordset object. 
Dim rsCounter As ADODB.Recordset 
Set rsCounter = New ADODB.Recordset 
Dim startDate As String, endDate As String, query As String 

query = "Exec ReadCntrs 0, '12/01/2011', '12/30/2011'" 

With rsCounter 
    ' Assign the Connection object. 
    .ActiveConnection = DBConn 

    .Open query 
    ' Copy the records into cell A1 on Sheet1. 
    Sheet1.Range("A1").CopyFromRecordset rsCounter 

    ' Tidy up 
    .Close 
End With 

DBConn.Close 
Set rsCounter = Nothing 
Set DBConn = Nothing 

ExitHere: 
    On Error Resume Next 
    DBConn.Close: Set DBConn = Nothing 
    Err.Clear 
    Exit Sub 

ErrHandler: 
    MsgBox Err.Number & Err.Description, vbExclamation 
    Resume ExitHere 

End Sub

來源

2011-08-22 Safran Ali

With rsCounter 
    ' Assign the Connection object. 
    .ActiveConnection = DBConn 

    .Open query 

    ' Write the column names into cell A1 on Sheet1. 
    Dim counter As Long 
    For counter = 0 To rsCounter.Fields.Count - 1 
     Sheet1.Range("A1").Offset(, counter).Value = rsCounter.Fields(counter).Name 
    Next 

    ' Copy the records into cell A2 on Sheet1. 
    Sheet1.Range("A2").CopyFromRecordset rsCounter 

    ' Tidy up 
    .Close 
End With

來源

2011-08-23 09:42:36 onedaywhen

rsCounter.Fields(i).Name - 其中i爲表示場地number--整數是如何正常訪問的字段名稱。

編輯 - 也得到場總數將使用rsCounter.Fields.Count

來源

2011-08-22 15:51:28 transistor1

如何獲取VBA中的列名？

回答

相關問題