sed替換（單行）C註釋與C++註釋

Question

如何使用sed將源文件中的所有C風格註釋替換爲C++風格。

所有這些：

int main() { 
    /* some comments */ 
    ... 

到：

int main() { 
    // some comments 
    ... 

所有評論都是單線和代碼之間有沒有像這樣：

int f(int x /*x-coordinate*/); 

，所以我想這：

sed -i 's/ \/\* .* \*\/\/\/* /g' src.c 

但它保持文件不變。 This後類似，但我想了解sed的表達式語法。由於「。」匹配任何字符，「*」匹配零個或多個某種模式。我假設「。*」匹配任何數字的任何字符。

Answer 1

sed -i 's:\(.*\)/[*]\(.*\)[*]/:\1 // \2:' FILE 

這將改變每一行是這樣的：

aaa /* test */ 

成這樣一行：

aaa // test 

如果你有在同一行更多的評論，你可以將這個更復雜的語法分析器，可以轉換如下行：

aaa /* c1 */ bbb /* c2 */ ccc 

到

aaa bbb ccc // c1 c2 

---

sed -i ':r s:\(.*\)/[*]\(.*\)[*]/\(.*\):\1\3 //\2:;tr;s://\(.*\)//\(.*\)://\2\1:;tr' FILE 

一個更復雜的情況是，當你有一行註釋裏面串，就像在call("/*string*/")。這裏是一個腳本c-comments.sed，來解決這個問題：

s:\(["][^"]*["]\):\n\1\n:g 
s:/[*]:\n&:g 
s:[*]/:&\n:g 
:r 
s:["]\([^\n]*\)\n\([^"]*\)":"\1\2":g 
tr 
:x 
s:\(.*\)\n/[*]\([^\n]*\)[*]/\n\(.*\)$:\1\3 // \2: 
s:\(.*\)\n\(.*\)//\(.*\)//\(.*\):\1\n\2 //\4\3: 
tx 
s:\n::g 

保存這個腳本到一個文件c-comments.sed，你這樣稱呼它：

sed -i -f c-comments.sed FILE