XSLT：與複雜分組有關的問題

Question

我正在努力爭取'爲每個小組'工作，我最近切換到了xslt 2，但仍有一些工作要做，以使其全部瞭解。我試圖清理從Framemaker MIF（flat xml）收到的一些文件，雖然在大多數情況下，數據非常乾淨，但這是一些例外，導致我瘋了。我已經在下面的XML中結合了一些典型的例子。我使用的例子與下劃線標籤有關，原則上這些文件的構建方式如下：如果您看到[下劃線/]標籤，所有後續兄弟姐妹需要加下劃線，直到您到達[EndUnderline /]標籤，所以我的目標是擺脫這兩個標籤，並將所有兄弟姐妹封裝在一個[u]標籤中。然而，問題是可能會有後續的[Underline /]標籤需要忽略，直到達到實際的[EndUnderline /]標籤。

讓我們試着對上面更加明顯，這是一個簡單的XML文件：

<TestFile> 
<!-- Para tag containing no underline tags --> 
<Para> 
    <Content>[text_not_underlined]</Content> 
</Para> 

<!-- correct encapsulation from source --> 
<Para> 
<Content> 
    <Underline/>[text_to_be_underlined]<EndUnderline/> 
    <p>Some test data</p> 
</Content> 
</Para> 

<!-- extra underline tag that should be ignored --> 
<Para> 
<Content> 
    <Underline/>[text_to_be_underlined] 
    <Underline/> 
    <EndUnderline/> 
    <p>Some other test data</p> 
</Content> 
</Para> 

<!-- some extra end underline tags that should be ignored --> 
<Para> 
<Content> 
    <EndUnderline/>[no_longer_underline]<EndUnderline/> 
    <p>: More data</p> 
</Content> 
</Para> 

</TestFile> 

這是我到現在爲止我的XSLT：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" indent="yes"/> 

<xsl:template match="/"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="@*|node()"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="Content"> 
<xsl:copy> 
    <xsl:for-each-group select="node()" group-ending-with="EndUnderline"> 
    <xsl:choose> 
    <xsl:when test="current-grouping-key()"> 
    <xsl:variable name="start" select="current-group()[self::Underline][1]"/> 
     <xsl:copy-of select="current-group()[$start >> .]"/> 
     <u> 
     <xsl:copy-of select="current-group()[. >> $start][not(self::Underline)][not(self::EndUnderline)]"/> 
     </u> 
     </xsl:when> 
    <xsl:otherwise> 
    <xsl:copy-of select="current-group()"/> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:for-each-group> 
</xsl:copy> 
</xsl:template> 
</xsl:stylesheet> 

這是結果：

<TestFile> 

<!-- Para tag containing no underline tags --> 
<Para> 
<Content> 
    <u/> 
</Content> 
</Para> 

<!-- correct encapsulation from source --> 
<Para> 
<Content> 
    <u>[text_to_be_underlined]</u> 
    <u/> 
</Content> 
</Para> 

<!-- extra underline tag that should be ignored --> 
<Para> 
<Content> 
    <u>[text_to_be_underlined]</u> 
    <u/> 
</Content> 
</Para> 

<!-- some extra end underline tags that should be ignored --> 
<Para> 
<Content> 
    <u/> 
    <u/> 
</Content> 
</Para> 
</TestFile> 

雖然這是我的目標：

<TestFile> 
<!-- Para tag containing no underline tags --> 
<Para> 
    <Content>[text_not_underlined]</Content> 
</Para> 

<!-- correct encapsulation from source --> 
<Para> 
<Content> 
    <u>[text_to_be_underlined]</u> 
    <p>Some test data</p> 
</Content> 
</Para> 

<!-- extra underline tag that should be ignored --> 
<Para> 
<Content> 
    <u>[text_to_be_underlined]</u> 
    <p>Some other test data</p> 
</Content> 
</Para> 
<!-- some extra end underline tags that should be ignored --> 
<Para> 
<Content> 
    [no_longer_underline] 
    <p>: More data</p> 
</Content> 
</Para> 
</TestFile> 

在此先感謝您的任何提示，可以指向正確的方向！

Answer 1

謝謝，但是這實際上只有在有開始標記和結束標記我假設之間的單一元素的工作。

無論如何，我發現同時感謝其他一些有用的互聯網人在回答中，所以讓我分享一下我們想出了在最後：

 <xsl:template match="Content"> 
    <xsl:copy> 
     <xsl:for-each-group select="node()" group-ending-with="EndUnderline"> 
      <xsl:variable name="start" select="current-group()[self::Underline][1]"/> 
      <xsl:choose> 
       <xsl:when test="$start"> 
        <!-- Content element contains at least one <Underline/> marker element, so we group all between the first <Underline/> tag until the first <EndUnderline/> tag --> 
        <xsl:apply-templates select="current-group()[$start >> .]"/> 
        <!-- Every tag before the first <Underline/> marker gets transformed as standard, all tags between the markers gets encapsulated in a <u> tag --> 
        <u> 
         <xsl:apply-templates select="current-group()[. >> $start][not(self::Underline)][not(self::EndUnderline)]"/> 
        </u> 
       </xsl:when> 
       <xsl:otherwise> 
        <!-- Apply standard transformation on current group (not containing underline tags...) --> 
        <xsl:apply-templates select="current-group()"/> 
       </xsl:otherwise> 
      </xsl:choose> 
     </xsl:for-each-group> 
    </xsl:copy> 
</xsl:template> 
<!-- Get rif of standalone end tags... --> 
<xsl:template match="EndUnderline"/> 

Answer 2

你說這是一個簡化的例子，所以我的解決方案可能不是你想要的。您是否嘗試過未使用分組？以下XSL似乎給出了正確的結果。

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes" /> 

    <xsl:template match="/ | * | text() | comment() "> 
     <xsl:copy> 
     <xsl:apply-templates select="* | text() | comment() " /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="p"> 
     <xsl:copy-of select="." /> 
    </xsl:template> 

    <xsl:template match="Content/text()"> 
     <xsl:choose> 
     <xsl:when test="preceding-sibling::Underline"></xsl:when> 
     <xsl:when test="following-sibling::EndUnderline"></xsl:when> 
     <xsl:otherwise> 
     <xsl:copy-of select="." /> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

    <xsl:template match="Content/Underline" /> 

    <xsl:template match="Content/EndUnderline"> 
     <xsl:choose> 
     <xsl:when test="preceding-sibling::Underline"> 
      <u><xsl:value-of select="preceding-sibling::text()[1]" /></u> 
     </xsl:when> 
     <xsl:otherwise> 
      <xsl:value-of select="preceding-sibling::text()[1]" /> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

</xsl:stylesheet>