複雜的xslt地址拆分

Question

我有一個地址，我需要在第一個空白空間後拆分（我認爲可以安全地假設街道名稱在第一個空格之後開始）。然後，我需要將每段文本（街道名稱/門號/郵政信箱）分配給不同的節點。所有標點符號也需要刪除。

的代碼需要採取這樣的：

<address>123 1st St., P.O. Box 321</address> 

，把它變成這樣：

<door_num>123</door_num> 
<street_name>1st St</street_name> 
<addr_postfix>PO Box 321</addr_postfix> 

我已經看到了如何給內的某個字符或位置分割字符串的幾個問題一個字符串，但從不使用這兩個參數。我最初以爲要掃描字符串並挑選出任何數字，但我認爲這不適用於P.O。箱號或編號的街道。

我在想我需要使用substring-before和substring-after操作符，但我不知道如何正確實現它們。此外，這是相當複雜的，我甚至不知道從哪裏開始

感謝，

艾倫

Answer 1

這解決了特定情況下的例如地址，可以讓你開始：

<xsl:template match="address"> 
    <door_num> 
     <xsl:value-of select="substring-before(., ' ')"/> 
    </door_num> 
    <street_name> 
     <xsl:value-of select="translate(substring-before(substring-after(., ' '), ','), '.', '')"/> 
    </street_name> 
    <addr_postfix> 
     <xsl:value-of select="translate(normalize-space(substring-after(., ',')), '.', '')"/> 
    </addr_postfix> 
</xsl:template> 

Answer 2

這裏是所提供的XML文檔的情況下工作的徹底轉變：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="address"> 
    <xsl:variable name="vNum" select="substring-before(.,' ')"/> 
    <xsl:variable name="vStreet" select= 
    "substring-before(substring-after(.,$vNum), ',')"/> 
    <xsl:variable name="vPOBox" select="substring-after(.,',')"/> 

    <door_num><xsl:value-of select="$vNum"/></door_num> 
    <street_name> 
    <xsl:value-of select="normalize-space(translate($vStreet, '.',''))"/> 
    </street_name> 
    <addr_postfix> 
    <xsl:value-of select="normalize-space(translate($vPOBox, '.',''))"/> 
    </addr_postfix> 
</xsl:template> 
</xsl:stylesheet> 

當應用所提供的XML文檔：

<address>123 1st St., P.O. Box 321</address> 

想要的，正確的結果產生：

<door_num>123</door_num> 
<street_name>1st St</street_name> 
<addr_postfix>PO Box 321</addr_postfix>