離開堆棧時自動釋放內存

Question

我想編寫一些內容，一旦動態分配地址空間的指針離開堆棧，就會自動釋放內存。 一個例子是：

procedure FillMemory (var mypointer); 
begin 
    // CopyMemory, Move, etc... with data 
end; 

procedure MyProcedure; 
var 
    MyPointer : Pointer; 
begin 
    MyPointer := VirtualAlloc (NIL, 1024, MEM_COMMIT or MEM_RESERVE, PAGE_EXECUTE_READWRITE); 
    FillMemory (MyPointer); 
    VirtualFree(MyPointer, 0, MEM_RELEASE); // I would like to avoid this... 
end; 

我可以使用字符串，但我也想避開他們（這我不敢肯定，如果字符串在堆棧中得到釋放反正...） 任何想法？

Answer 1

要擴大我的意見，並與亞略討論，

如果你只是想要一個原始的內存塊，請使用動態的array of byte。編譯器將生成代碼以在方法結束時釋放此內存：

type 
    TBytes = array of Byte; // omit for newer Delphi versions 

procedure FillMemory(var Bytes: TBytes); 
begin 
    { passing in here will increase the reference count to 2 } 
    // CopyMemory, Move, etc... with data 
end; // then drop back to 1 

procedure MyProcedure; 
var 
    Buffer : TBytes; 
begin 
    SetLength(Buffer, 1024); // buffer has reference count of 1 
    FillMemory (Buffer); 
end; // reference count will drop to 0, and Delphi will free memory here 

希望這一切都有道理。這是午夜，所以我沒有感覺到最清醒的...

Answer 2

託管類型的引用已計數，當計數降至零時，它們即已完成。如果您有一個局部變量，那麼當它超出範圍時，其引用計數將降爲零。

所以，你可以創建一個TInterfacedObject的後代，你使用的是一個接口。事情是這樣的：

type 
    TLifetimeWatcher = class(TInterfacedObject) 
    private 
    FDestroyProc: TProc; 
    public 
    constructor Create(const DestroyProc: TProc); 
    destructor Destroy; override; 
    end; 

constructor TLifetimeWatcher.Create(const DestroyProc: TProc); 
begin 
    inherited Create; 
    FDestroyProc := DestroyProc; 
end; 

destructor TLifetimeWatcher.Destroy; 
begin 
    if Assigned(FDestroyProc) then 
    FDestroyProc(); 
    inherited; 
end; 

然後，您可以使用它像這樣：

procedure MyProcedure; 
var 
    MyPointer: Pointer; 
    LifetimeWatcher: IInterface; 
begin 
    MyPointer := VirtualAlloc (NIL, 1024, MEM_COMMIT or MEM_RESERVE, 
    PAGE_EXECUTE_READWRITE); 
    LifetimeWatcher := TLifetimeWatcher.Create(
    procedure 
    begin 
     VirtualFree(MyPointer, 0, MEM_RELEASE); 
    end; 
) 
    FillMemory(MyPointer); 
end; 

當LifetimeWatcher葉範圍，則執行被破壞，你傳遞給TLifetimeWatcher.Create實現對象和程序。

將專門研究這個想法專門用於您的用例將會很容易。這將使呼叫站點的代碼更加簡潔。

這將是這樣的：

function VirtualAllocAutoRelease(Size: SIZE_T; Protect: DWORD; 
    out LifetimeCookie: IInterface): Pointer; 
var 
    Ptr: Pointer; 
begin 
    Ptr := VirtualAlloc(nil, Size, MEM_COMMIT or MEM_RESERVE, Protect); 
    Win32Check(Ptr<>nil); 
    LifetimeCookie := TLifetimeWatcher.Create(
    procedure 
    begin 
     VirtualFree(Ptr, 0, MEM_RELEASE); 
    end 
); 
    Result := Ptr; 
end; 

你會使用這樣的：

procedure MyProcedure; 
var 
    MyPointer: Pointer; 
    LifetimeWatcher: IInterface; 
begin 
    MyPointer := VirtualAllocAutoRelease(1024, PAGE_EXECUTE_READWRITE, 
    LifetimeWatcher); 
    FillMemory(MyPointer); 
end;