Haskell - 合併排序，整理單詞和數字

Question

我已經在Haskell中編寫了一個合併排序，它在使用數字而不是單詞時起作用，我認爲它會。在使用文字和字母時，我只會得到「不在範圍內」。我究竟做錯了什麼？

這裏是我的代碼：

merge :: Ord a => [a] -> [a] -> [a] 
merge [] ys = ys 
merge xs [] = xs 
merge (x:xs) (y:ys) 
    | x <= y = x : merge xs (y:ys) 
    | otherwise = y : merge (x:xs) ys 

mergeSort :: Ord a => [a] -> [a] 
mergeSort [] = [] 
mergeSort [x] = [x] 
mergeSort xs 
    = merge (mergeSort top) (mergeSort bottom) 
    where 
    (top, bottom) = splitAt (length xs `div` 2) xs 

Answer 1

你進入你的話也是這樣嗎？

[this,is,an,example,sentence] 

語法不正確。如果你想輸入一個字符串，你必須encapsulte它在雙引號（"）：

["this","is","an","example","sentence"] 

如果這不是你的錯誤，隨意忽略這個答案。

Answer 2

您的代碼正常工作。

但是，我建議分割列表在一次通過，而不使用length。當然，這裏的順序並不重要，只是我們有兩個大小相同的列表。你可以這樣做的：

splitList [] = ([],[]) 
splitList [x] = ([x],[]) 
splitList (x:y:zs) = let (xs,ys) = splitList zs in (x:xs, y:ys) 

...或尾遞歸...

splitList zs = go zs [] [] where 
    go [] xs ys = (xs, ys) 
    go [x] xs ys = (x:xs, ys) 
    go (x:y:zs) xs ys = go zs (x:xs) (y:ys)  

...或者使用索引...

splitList xs = (go even, go odd) where 
    go f = map snd $ filter (f.fst) $ indexed 
    indexed = zip [0..] xs 

...或使用摺疊...

import Data.List 

splitList zs = snd $ foldl' go (True,([],[])) zs where 
    go (True,(xs,ys)) x = (False,(x:xs,ys)) 
    go (False,(xs,ys)) x = (True,(xs,x:ys))