雖然在Microsoft SQL Server 2008中循環

Question

我試圖想出一個使用Microsoft SQL Server的while循環的簡單示例。 在這裏我循環了所有以temp開頭的表格。

Declare @Object_ID int,@Name varchar(50) 
set @Object_ID = 0 
while exists (
    select * from 
    sys.tables 
    where type = 'u' 
    and object_ID > @Object_ID 
    and Name like 'Temp%' 
) BEGIN 
    select top 1 @Object_ID=Object_ID,@Name=Name 
    from sys.tables 
    where type = 'u' 
    and object_ID > @Object_ID 
    and Name like 'Temp%' 
    order by Object_ID 
    exec('Select ''' + @Name + ''' as TableName,count(*) AS Counter from ' + @Name) 
END 

我的問題是：現在我已經通過表循環了，如何使用我用exec命令收集的信息？ 換句話說，我可以將從exec命令返回的表存儲到變量中嗎？

Answer 1

這裏是我做這種工作的這些日子：

DECLARE 
    @LoopId  int 
,@Command varchar(500) 

DECLARE @List TABLE 
(
    TableName sysname not null 
    ,LoopId  int  not null identity(1,1) 
) 

DECLARE @Results TABLE 
(
    TableName sysname not null 
    ,Counter int  not null 
) 

-- Load with items you wish to review 
INSERT @List (TableName) 
select name 
    from sys.tables 
    where Name like 'Temp%' 
    order by Name desc 

SET @LoopId = @@rowcount 

-- Go through list and process each item 
WHILE @LoopId > 0 
BEGIN 
    SELECT @Command = 'SELECT ''' + TableName + ''' as TableName, count(*) as Counter from ' + TableName 
    from @List 
    where LoopId = @LoopId 

    -- Load results in temp table 
    INSERT @Results (TableName, Counter) 
    execute (@Command) 

    SET @LoopId = @LoopId - 1 
END 

SELECT * from @Results 

Answer 2

您可以存儲臨時表，類似於this example。

Answer 3

如果我正確理解你的問題的話，當然，看here

只要插入到表中的VAR每次迭代，然後做什麼就可以了之後。

Answer 4

如果你想用這種動態SQL來收集信息，那麼你必須有一個地方來保存這些信息 - 臨時表，永久表或表變量。然後，你應該能夠做這樣的事情：

Declare @Object_ID int,@Name varchar(50) 
DECLARE 
    @tbl TABLE (table_name SYSNAME, table_count INT) 

set @Object_ID = 0 
while exists (
    select * from 
    sys.tables 
    where type = 'u' 
    and object_ID > @Object_ID 
    and Name like 'Temp%' 
) BEGIN 
    select top 1 @Object_ID=Object_ID,@Name=Name 
    from sys.tables 
    where type = 'u' 
    and object_ID > @Object_ID 
    and Name like 'Temp%' 
    order by Object_ID 

    INSERT INTO @tbl (table_name, table_count) 
    exec('Select ''' + @Name + ''' as TableName,count(*) AS Counter from ' + @Name) 
END 

SELECT * FROM @tbl