如何將正確的庫與GLFW鏈接爲cmake中的外部項目？

Question

我包括這樣GLFW：

ExternalProject_Add(glfw-external 
    URL https://github.com/glfw/glfw/releases/download/3.2.1/glfw-3.2.1.zip 
    PREFIX ${CMAKE_CURRENT_BINARY_DIR}/glfw 
    INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/install 
    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR> 
) 

add_dependencies(ShittyLife glfw-external) 

if(UNIX) 
    set(GLFW_LIB <What to put here?> libglfw3.a) 
else() 
    set(GLFW_LIB ${install_dir}/lib/glfw3.lib) 
endif() 

該庫是在以後使用GLFW_LIB變量掛鉤。

它在Windows上很好用，但在Linux上我缺少一些庫。 glfw網頁爲此提供瞭解決方案，但是它們都沒有與ExternalProject_add兼容。

任何想法，我怎麼能找出所需的庫，最好以一種方式，將跨越不同的機器/發行版？

在情況下，它是有幫助的，這裏的錯誤試圖建立時，我得到：

相關位：

/usr/bin/ld: /home/molion/Desktop/ShittyLife/build/install/lib/libglfw3.a(x11_window.c.o): undefined reference to symbol 'XConvertSelection' 
//usr/lib/x86_64-linux-gnu/libX11.so.6: error adding symbols: DSO missing from command line 

所有這一切：

[ 94%] Building CXX object CMakeFiles/ShittyLife.dir/src/main.cpp.o 
[100%] Linking CXX executable ShittyLife 
/usr/bin/ld: /home/molion/Desktop/ShittyLife/build/install/lib/libglfw3.a(x11_window.c.o): undefined reference to symbol 'XConvertSelection' 
//usr/lib/x86_64-linux-gnu/libX11.so.6: error adding symbols: DSO missing from command line 
collect2: error: ld returned 1 exit status 
CMakeFiles/ShittyLife.dir/build.make:95: recipe for target 'ShittyLife' failed 
make[2]: *** [ShittyLife] Error 1 
CMakeFiles/Makefile2:68: recipe for target 'CMakeFiles/ShittyLife.dir/all' failed 
make[1]: *** [CMakeFiles/ShittyLife.dir/all] Error 2 
Makefile:83: recipe for target 'all' failed 
make: *** [all] Error 2 

Answer 1

GLFW提供了CMake的配置文件包，因此您應該使用find_package來查找它。

但因爲這是唯一可用的ExternalProject_Add已運行後沒有在配置時，你必須創建一個超級項目，並添加自己的項目作爲ExternalProject過，像這樣：

ExternalProject_Add(glfw-test 
    SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src 
    PREFIX ${CMAKE_CURRENT_BINARY_DIR} 
    INSTALL_COMMAND "" 
    CMAKE_CACHE_ARGS "-DCMAKE_PREFIX_PATH:STRING=${GLFW_INSTALL_PREFIX}/lib/cmake" 
    DEPENDS glfw-external 
) 

與set(GLFW_INSTALL_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/glfw_install")和GLFW_INSTALL_PREFIX也用於GLFW ExternalProject_Add。

然後可以使用

find_package(glfw3 REQUIRED) 
find_package(OpenGL REQUIRED) 

和

target_link_libraries(${PROJECT_NAME} 
    glfw 
    OpenGL::GL 
) 

在您的項目。

---

而不是使用ExternalProject，你還可以按照the GLFW suggestion的。

Answer 2

如果您願意使用包管理器來處理依賴關係，您可以考慮使用Hunter將GLFW添加到項目中。 Hunter是用本地CMake編寫的，並且已經在引擎蓋下使用了ExternalProject。但是使用imo要容易得多。

有一個簡短的（和稀疏的）documentation page。基本上，你的CMakeLists.txt將類似於以下...

# CMake version 3.0 or higher is required for the Hunter package manager. 
cmake_minimum_required(VERSION 3.0) 

# Include the Hunter package manager module. 
include("cmake/HunterGate.cmake") 

# Ensure a reproducible build by locking down the Hunter package versions. 
HunterGate(
    URL "https://github.com/ruslo/hunter/archive/v0.19.77.tar.gz" 
    SHA1 "8898dd07756c408c63c63add903c8600c4cf4c0e") 

# Your project name here. 
project(my_project_name) 

# Tell Hunter which packages to pull in for our project. 
hunter_add_package(glfw) 
find_package(glfw3 REQUIRED) 

# Link against your target. 
target_link_libraries(my_target_name glfw) 

神奇HunterGate線可以與每個新Hunter release被發現。我最近發佈了codecast on Hunter，如果你迷路了，它會幫助你逐步完成步驟。

Answer 3

這是我已經使用了一段時間的CMakeLists.txt之一。非常簡單，你告訴CMake glfw3所在的位置，這樣它的CMake就可以完成它的工作，然後將glfw作爲鏈接庫添加到include目錄中。這與在視覺工作室中包含GLFW沒有什麼不同。

cmake_minimum_required(VERSION 3.7) 
project(SkyGames) 

set(CMAKE_CXX_STANDARD 14) 

set(SOURCE_FILES main.cpp) 
add_executable(SkyGames ${SOURCE_FILES}) 

########################### 
# GLFW 
########################### 

set(GLFW_BUILD_DOCS OFF CACHE BOOL "" FORCE) 
set(GLFW_BUILD_TESTS OFF CACHE BOOL "" FORCE) 
set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE) 

add_subdirectory(${PROJECT_SOURCE_DIR}/Externals/GLFW3) 

target_link_libraries(SkyGames glfw) 
include_directories(SkyGames ${GLFW_INCLUDE_DIR}) 

########################### 
# GLEW 
########################### 
add_definitions(-DGLEW_STATIC) 
set(GLEW_ROOT_DIR ${PROJECT_SOURCE_DIR}/Externals/glew2s) 
set(GLEW_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/Externals/glew2s/include) 
set(GLEW_LIBRARY ${PROJECT_SOURCE_DIR}/Externals/glew2s/lib/Release/Win32/glew32s.lib) 
find_package(GLEW REQUIRED) 
include_directories(${GLEW_INCLUDE_DIR}) 

########################## 
# OPENGL 
########################## 

find_package(OpenGL REQUIRED) 
target_link_libraries(SkyGames ${GLEW_LIBRARY} ${OPENGL_LIBRARY} ${OPENGL_gl_LIBRARY} ${OPENGL_glu_LIBRARY})