XSLT的換行符

Question

分裂地址我有一個XML像這樣一個地址：

<ADDRESS>SHIPPING ADDRESS 1 
SHIPPING ADDRESS 2 
SHIPPING ADDRESS 3</ADDRESS> 

，我需要將其轉換爲：

<ADDRESS1>SHIPPING ADDRESS 1</ADDRESS1> 
<ADDRESS2>SHIPPING ADDRESS 2</ADDRESS2> 

（忽略第三行）。

注：我使用XSLT 1.0

Answer 1

如果你只是想前兩行，你可以這樣做：

<xsl:template match="ADDRESS"> 
    <ADDRESS1> 
     <xsl:value-of select="substring-before(., '&#10;')" /> 
    </ADDRESS1> 
    <ADDRESS2> 
     <xsl:value-of select="substring-before(substring-after(., '&#10;'), '&#10;')" />  
    </ADDRESS2> 
</xsl:template> 

這是假設至少有三條線。否則它會變得更復雜一點。例如，您可以使用：

<xsl:template match="ADDRESS"> 
    <xsl:variable name="address" select="concat(., '&#10;&#10;')" /> 
    <ADDRESS1> 
     <xsl:value-of select="substring-before($address, '&#10;')" /> 
    </ADDRESS1> 
    <ADDRESS2> 
     <xsl:value-of select="substring-before(substring-after($address, '&#10;'), '&#10;')" /> 
    </ADDRESS2> 
</xsl:template> 

創建兩條地址線，無論源地址有多少行。

Answer 2

這裏是另外一個答案，對於任何數量的行工作：

<xsl:template match="ADDRESS"> 
    <xsl:call-template name="splitAddress"> 
     <xsl:with-param name="string" select="."/> 
    </xsl:call-template> 
    </xsl:template> 

    <xsl:template name="splitAddress"> 
    <xsl:param name="string"/> 
    <xsl:param name="AddrNo" select="1"/> 
    <xsl:choose> 


    <xsl:when test="$AddrNo = 2"> 
    <xsl:element name="ADDRESS{$AddrNo}"> 
     <xsl:value-of select="substring-before($string, '&#10;')"/> 
    </xsl:element> 
    </xsl:when> 


     <xsl:when test="contains($string, '&#10;')"> 
     <xsl:element name="ADDRESS{$AddrNo}"> 
      <xsl:value-of select="substring-before($string, '&#10;')"/> 
     </xsl:element> 
     <xsl:call-template name="splitAddress"> 
      <xsl:with-param name="string" select="substring-after($string, '&#10;')"/> 
      <xsl:with-param name="AddrNo" select="$AddrNo + 1"/> 
     </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
     <xsl:element name="ADDRESS{$AddrNo}"> 
      <xsl:value-of select="$string"/> 
     </xsl:element> 
     </xsl:otherwise> 
    </xsl:choose> 
    </xsl:template> 

- 編輯 - 我錯過了要求停止第二地址行之後。我已根據需要插入xsl:when以結束處理：此處的條件可根據需要進行編輯。