新線到HTML換行符使用XSLT

Question

我有下面的XML：

<RichText> 
    Text 
    Text 
    Text 
</RichText> 

我想輸出使用XSLT 1.0以下的HTML（2.0，如果我真的需要的話）：

<p> 
    Text<br/> 
    Text<br/> 
    Text 
</p> 

<xsl:template match="text()"> 
    <xsl:param name="text" select="."/> 

    <!-- Because we would rely on $text containing a line break when using 
     substring-before($text,'&#10;') and the last line might not have a 
     trailing line break, we append one before doing substring-before(). --> 
    <xsl:value-of select="substring-before(concat($text,'&#10;'),'&#10;')"/> 
    <br/> 

    <xsl:if test="contains($text,'&#10;')"> 
    <xsl:apply-templates select="."> 
     <xsl:with-param name="text" select="substring-after($text,'&#10;')"/> 
    </xsl:apply-templates> 
    </xsl:if> 
<xsl:template> 

此輸出：

我使用下面的XSL它靠攏試圖

<p><br>     
    Text<br>     
    Text<br>     
    Text<br> 
<br></p> 

Answer 1

爲了您的XSLT 1.0解決方案，我想你需要的是一些xsl:if測試，以檢測是否有之前和您正在處理的當前行之後的非空白文本。

試試這個XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output method="html" /> 

<xsl:template match="RichText"> 
    <p><xsl:apply-templates /></p> 
</xsl:template> 

<xsl:template match="text()"> 
    <xsl:param name="text" select="."/> 

    <xsl:variable name="startText" select="substring-before(concat($text,'&#10;'),'&#10;')" /> 
    <xsl:variable name="nextText" select="substring-after($text,'&#10;')"/> 
    <xsl:if test="normalize-space($startText)"> 
     <xsl:value-of select="$startText"/> 
     <xsl:if test="normalize-space($nextText)"> 
     <br /> 
     </xsl:if> 
    </xsl:if> 

    <xsl:if test="contains($text,'&#10;')"> 
     <xsl:apply-templates select="."> 
     <xsl:with-param name="text" select="$nextText"/> 
     </xsl:apply-templates> 
    </xsl:if> 
</xsl:template> 
</xsl:stylesheet> 

Answer 2

嘗試下面的腳本：

<?xml version="1.0" encoding="UTF-8" ?> 
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 
    <xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" /> 

    <xsl:template match="RichText"> 
    <p> 
     <xsl:variable name="txt" select="tokenize(., '&#xA;')"/> 
     <xsl:variable name="len" select="count($txt)"/> 
     <xsl:for-each select="subsequence($txt, 2, $len - 2)"> 
     <xsl:value-of select="replace(replace(.,'\s+$',''),'^\s+','')"/> 
     <xsl:if test="position() &lt; last()"> 
      <xsl:text disable-output-escaping="yes">&lt;br/&gt;</xsl:text> 
     </xsl:if> 
     <xsl:text>&#xA;</xsl:text> 
     </xsl:for-each> 
    </p> 
    </xsl:template> 

</xsl:transform> 

我使用XSLT 2.0，作爲一個版本更簡單寫。

有可能重寫它使用XSLT 1.0，但必須使用等效 1.0解決方案：

• 符號化，
• 子，
• 和修整。