如何將更高的任務優先級設置爲Parallel.Async後臺任務？

Question

我需要爲Parallel.Async後臺任務分配更高的任務優先級。由於OmniThreadLibrary有SetPriority：我如何設置此Parallel.Async任務的特定優先級？

uses 
    CodeSiteLogging, 
    OtlParallel, OtlTaskControl, OtlTask; 

procedure TForm2.btnParallelAsyncClick(Sender: TObject); 
begin 
    CodeSite.Send('btnParallelAsyncClick 1'); 

    Parallel.Async(
    procedure(const task: IOmniTask) 
    var 
     a: Integer; 
    begin 
     // executed in background thread: 
     a := 1 + 1; 
     Sleep(2000); 
     CodeSite.Send('Executed in Async Thread', a); 

     task.Invoke(// used to execute code in main thread 
     procedure 
     begin 
      CodeSite.Send('task.Invoke executed in main thread', a); 
     end); 

     Sleep(2000); 
     CodeSite.Send('Again executed in Async Thread', a); 
    end, 
    Parallel.TaskConfig.OnTerminated(
    procedure(const task: IOmniTaskControl) 
    begin 
     // executed in main thread: 
     CodeSite.Send('After background thread termination: Executed in Main Thread'); 
    end 
    ) 
    ); 

    CodeSite.Send('btnParallelAsyncClick 2'); 
end; 

Answer 1

更換

Parallel.TaskConfig.OnTerminated(... 

與例如

Parallel.TaskConfig.SetPriority(tpAboveNormal).OnTerminated(... 

可能值的優先級是

tpIdle, tpLowest, tpBelowNormal, tpNormal, tpAboveNormal, tpHighest 

請注意，這隻會影響給予優先線程內你的過程並沒有給過程本身更高的優先權。有關更多信息，請參閱SetThreadPriority函數的文檔。