批處理文件讀取尚未使用的文本的第一行，然後標記爲已使用

Question

我有一個要求，在Windows批處理文件中，從文本文件中讀取第一個可用行，將它傳遞給變量並標記爲已使用的名稱\行

該文件的一個示例如下。

蘋果
梨
橙色

該腳本將與「蘋果」入手，通過「蘋果」到一個變量中的腳本以後使用（我知道如何做到這一點位），然後回寫該行讀取&蘋果，'&'作爲一個標誌，說它已被使用。

然後將文件看起來像：

&蘋果
梨樹下一次該批處理文件運行，將採取「梨」
橙色

，它傳遞給一個變量，它標記用&使它看起來像：

&蘋果
&梨
橙色

我開始試圖找到'&'，然後試圖移動到下一行，但我失敗後大約12小時的嘗試。這是我到目前爲止..並不多：

for/f「tokens = 1」％l in（'name.txt'）do（Find/v「&」/ v「^ ----^$「）（對於/ F％N在（％升）DO（設定新名稱=％N））

由於

Answer 1

上the.file運行此將修改依次在每個線;

@echo off 
setlocal enabledelayedexpansion 
type nul > the.file.temp 
set last= 
for /F "tokens=*" %%A in (the.file) do (
    set line=%%A 
    if "!line:~0,1!" neq "&" if "!last!" equ "" (
     set last=!line! 
     set line=^&!line! 
    ) 
    echo !line! >> the.file.temp 
) 

echo last value is !last! 
type the.file.temp > the.file 

（如果該行不&和可變last開始是空的，放在last &行修改line與一家領先的&，始終追加line到一個臨時文件，重命名完成時）

Answer 2

Alex k。有一個很好的答案，可能在大多數情況下都很好。 （我upvoted。）

但是，它會破壞包含!的任何文本。該限制可以通過在循環內開啓和關閉延遲擴展來解決。

該解決方案對於大小合理的文件可能足夠快。但是對於大文件，FOR循環會變得很慢。

我測試了一個包含2817行的190kb文件，並且Alex K.解決方案花了20秒時間進行一次運行。

這是一個完全不同的解決方案，不使用任何循環來處理0中相同的190kb文件。07秒 - 285倍的速度:)

@echo off 
setlocal enableDelayedExpansion 
set "file=test.txt" 
findstr /bv "$ &" "%file%" >"%file%.available" 
set "var=" 
<"%file%.available" set /p "var=" 
if defined var (
    >"%file%.new" (
    findstr /b "&" "%file%" 
    <nul set /p "=&" 
    type "%file%.available" 
) 
    move /y "%file%.new" "%file%" >nul 
) 
del "%file%.available" 

echo var=!var! 

更新：作爲評論的要求，這裏是代碼的大量註釋的版本。

@echo off 
setlocal enableDelayedExpansion 

:: Define the file to process 
set "file=test.txt" 

:: Write the unused lines to a temporary "available" file. We don't want any 
:: empty lines, so I strip them out here. There are two regex search strings; 
:: the first looks for empty lines, the second for lines starting with &. 
:: The /v option means only write lines that don't match either search string. 
findstr /bv "$ &" "%file%" >"%file%.available" 

:: Read the first available line into a variable 
set "var=" 
<"%file%.available" set /p "var=" 

:: If var defined, then continue, else we are done 
if defined var (

    REM Redirect output to a "new" file. It is more efficient to redirect 
    REM the entire block once than it is to redirect each command individulally 
    >"%file%.new" (

    REM Write the already used lines to the "new" file 
    findstr /b "&" "%file%" 

    REM Append the & without a new line 
    <nul set /p "=&" 

    REM Append the unused lines from the "available" file. The first appended 
    REM line is marked as used because of the previously written & 
    type "%file%.available" 
) 

    REM Replace the original file with the "new" content 
    move /y "%file%.new" "%file%" >nul 
) 

:: Delete the temp "available" file 
del "%file%.available" 

:: Display the result 
echo var=!var! 

我沒有測試過這一點，但我才意識到我可以寫寫入可用線以尋找與比&以外的字符開頭的行線：

findstr "^[^&]" "%file%" >"%file%.available"