如何獲取在批處理文件中添加/修改過的文件

Question

我有以下批處理文件，它將具有.sql結尾的文件夾中的所有文件連接起來。

set func=%~dp0%Stored Procedures\*.sql 
for %%i in (%func%) do type "%%i" >>InstallScript.sql 

我們使用SVN作爲我們的倉庫，我們使用分支。目前該腳本連接了所有的.sql文件，甚至連那些沒有改變的文件。我想改變它，所以它只連接在創建分支後修改和/或創建的文件。我們可以通過查看每個文件夾中的.svn文件夾的日期時間（有一個存儲過程，視圖，函數子文件夾）來實現。但我不知道如何用批處理文件來做到這一點。

理想情況下是這樣的（僞代碼）：

set func=%~dp0%Stored Procedures\*.sql 
set branchDateTime=GetDateTime(%~dp0%.svn) <- Gets the datetime when the .svn folder was created 

for %%i in (%func%) 
{ 
    if(%%i.LastModifiedOrCreated > branchDateTime) 
    do type "%%i" >> InstallScript.sql 
} 

感謝布朗博士，我最終得到這個（任何人需要類似的東西）：

@echo off 
cls 

echo --Install Script Generated For MMH Database %DATE% %TIME% > InstallScript.sql 

set branch=%~dp0.svn 
for %%i in (%branch%) do set SvnFileDate=%%~ti 
set year=%SvnFileDate:~8,2% 
set month=%SvnFileDate:~0,2% 
set day=%SvnFileDate:~3,2% 
set hours=%SvnFileDate:~11,2% 
set minutes=%SvnFileDate:~14,2% 
set datetime=%year%%month%%day%%hours%%minutes% 

:: Folder for Functions 
set func=%~dp0%Functions\*.sql 

setlocal enableextensions enabledelayedexpansion 

@for %%i in (%func%) do set FuncFileDate=%%~ti&^
set year2=!FuncFileDate:~8,2!&^
set month2=!FuncFileDate:~0,2!&^
set day2=!FuncFileDate:~3,2!&^
set hours2=!FuncFileDate:~11,2!&^
set minutes2=!FuncFileDate:~14,2!&^
set datetime2=!year2!!month2!!day2!!hours2!!minutes2!&^

if "!datetime!" LSS "!datetime2!" type "%%i" >> InstallScript.sql 

:: I would add similiar code for each folder, one for Views, Stored Procs, etc... 

endlocal 


pause 

Answer 1

的第一步，獲取.svn文件夾的日期時間如下所示：

for %%i in (.svn) do set FileDate=%%~ti 

您可能必須重新排序該行以相當的日期 - 時間格式的結果：

for %%i in (.svn) do set FileDate=%%~ti 
set year=%FileDate:~6,4% 
set month=%FileDate:~3,2% 
set day=%FileDate:~0,2% 
set hours=%FileDate:~11,2% 
set minutes=%FileDate:~14,2% 
set datetime=%year%%month%%day%%hours%%minutes% 
echo %datetime% 

第二部分是一點點更復雜，你需要mutiline命令，推遲擴張和比較：

setlocal enabledelayedexpansion 

@for %%i in (*.sql) do set FileDate=%%~ti&^
set year2=!FileDate:~6,4!&^
set month2=!FileDate:~3,2!&^
set day2=!FileDate:~0,2!&^
set hours2=!FileDate:~11,2!&^
set minutes2=!FileDate:~14,2!&^
set datetime2=!year2!!month2!!day2!!hours2!!minutes2!&^
if "!datetime!" LSS "!datetime2!" type "%%i" >> InstallScript.sql 

確保不在多行部分輸入任何額外的空格。希望這可以幫助。