着色灰度圖像as3

Question

我需要動態地使用ActionScript 3.0爲灰度漸變位圖着色。漸變從白到黑，最深的顏色必須是0xFF0000，最輕的是0xFFFFFF。嘗試調色板圖和ColorMatrixFilter混合結果並沒有穩定的解決方案。

Answer 1

通過在紅色通道上構建一個具有255偏移量的矩陣（除此之外是一個單位矩陣），可能對ColorMatrixFilter非常有用。

此示例文檔類假定FLA庫中有一個720×480的輸出符號「GradientBMD」這是一個flash.display.BitmapData子類：

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
    import flash.geom.Point; 
    import flash.filters.*; 

    public class GreyscaleDemo extends Sprite 
    { 
     public function GreyscaleDemo() 
     { 
      var bmd:BitmapData = new GradientBMD(720,480); 

      var matrix:Array = new Array(); 
      matrix = matrix.concat([1,0,0,0,255]); 
      matrix = matrix.concat([0,1,0,0,0]); 
      matrix = matrix.concat([0,0,1,0,0]); 
      matrix = matrix.concat([0,0,0,1,0]); 

      var colorFilter:ColorMatrixFilter = new ColorMatrixFilter(matrix); 
      bmd.applyFilter(bmd, bmd.rect, new Point(0,0), colorFilter); 

      var bitmap:Bitmap = new Bitmap(bmd); 
      this.addChild(bitmap); 
     } 
    } 
} 

您還可以創建充滿顏色的新位圖數據你想要的梯度遞減至（代替黑色），並將其複製到您的梯度BlendMode.ADD：

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
    import flash.display.BlendMode; 
    import flash.geom.Point; 

    public class GreyscaleDemo extends Sprite 
    { 
     public function GreyscaleDemo() 
     { 
      var bmd:BitmapData = new GradientBMD(720,480); 
      var bitmap:Bitmap = new Bitmap(bmd); 
      this.addChild(bitmap); 

      var bmd2:BitmapData = new BitmapData(720, 480, false, 0xFF0000); 
      bmd.draw(bmd2, null, null, BlendMode.ADD, bmd.rect,false); 
     } 
    } 
} 

Answer 2

除了使用的ColorMatrixFilter（在另一個答案所述），你也可以使用的的BlendMode = 「亮度」選項也是如此。

我對在ActionScript灰度圖像一篇博客文章中，這可能有助於： http://flexdevtips.blogspot.com/2011/01/grayscale-images-progressbar-rating.html

Answer 3

 var color:uint = 0xFF0000; 
     var r:uint = (color >> 16) & 0xFF; 
     var g:uint = (color >> 8) & 0xFF; 
     var b:uint = color & 0xFF; 

     var n:Number = 1/3; 

     var matrix:Array = new Array(); 
     matrix = matrix.concat([n,n,n,0,r]); 
     matrix = matrix.concat([n,n,n,0,g]); 
     matrix = matrix.concat([n,n,n,0,b]); 
     matrix = matrix.concat([0,0,0,1,0]); 

     _bitmapData.applyFilter(_bitmapData, _bitmapData.rect, new Point(), new ColorMatrixFilter(matrix));'