停止窗體幾乎立即關閉第二個應用程序實例時在屏幕上快速閃爍

Question

我有一個應用程序在主窗體的OnCreate期間檢查應用程序的另一個實例是否已通過創建互斥體運行。如果是，則第二個實例將消息傳遞給第一個實例，然後關閉它。它工作正常，除了第二個應用程序的一小竅門，它在屏幕關閉之前在屏幕上快速閃爍。

我有一個醜陋的啓動應用程序與主窗體WindowState設置爲wsMinimize，然後使用延遲1ms的計時器來最大化窗體。但這似乎是一個可怕的黑客。

有什麼更好的點子？

procedure TMyAwesomeForm.FormCreate(Sender: TObject); 
var 
    h: HWND; 
begin 
    // Try to create mutex 
    if CreateMutex(nil, True, '6EACD0BF-F3E0-44D9-91E7-47467B5A2B6A') = 0 then 
    RaiseLastOSError; 

    // If application already running 
    if GetLastError = ERROR_ALREADY_EXISTS then 
    begin 
    // Prevent this instance from being the receipient of it's own message by changing form name 
    MyAwesomeForm.Name := 'KillMe'; 

    // If this instance was started with parameters: 
    if ParamCount > 0 then 
    begin 
     h := FindWindow(nil, 'MyAwesomeForm'); 

     //Pass the parameter to original application 
     SendMessage(h, WM_MY_MESSAGE, strtoint(ParamStr(1)),0); 
    end; 

    // Shut this instance down - there can be only one 
    Application.Terminate; 
    end; 

    // Create Jump Lists  
    JumpList := TJumpList.Create; 
    JumpList.ApplicationId := 'TaskbarDemo.Unique.Id'; 
    JumpList.DeleteList; 
    CreateJList(); 
end; 

Answer 1

不要在窗體類中執行你的檢查，因爲表單會被創建出來。

恕我直言，與你一樣執行檢查的更好的地方是.dpr文件本身。

例如：

program Project3; 

uses 
    Forms, 
    Windows, //<--- new citizens here 
    SysUtils, 
    Messages, 
    Unit1 in 'Unit1.pas' {Form1}; 

{$R *.res} 

function IsAlreadyRunning: Boolean; 
var 
    h: HWND; 
begin 
    //no comments, sorry, but I don't use comments to explain what the 
    //code explains by itself. 
    Result := False; 

    if CreateMutex(nil, True, '6EACD0BF-F3E0-44D9-91E7-47467B5A2B6A') = 0 then 
    RaiseLastOSError; 

    if GetLastError = ERROR_ALREADY_EXISTS then 
    begin 
    if ParamCount > 0 then 
    begin 
     h := FindWindow(nil, 'MyAwesomeForm'); 
     if h <> 0 then 
     PostMessage(h, WM_MY_MESSAGE, strtoint(ParamStr(1)),0); 
     Result := True; 
    end; 
    end; 
end; 

begin 
    if not IsAlreadyRunning then 
    begin 
    Application.Initialize; 
    Application.MainFormOnTaskbar := True; 
    Application.CreateForm(TForm1, Form1); 
    Application.Run; 
    end; 
end.