當這個字符串與一個句子的一部分匹配時從數組中刪除字符串 - Perl

Question

我匹配字符串中的多個模式來填充一個數組。輸入文件看起來是這樣的：

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins # 2.8 
My father [père;parent;papa] lives in New-York # Mon père vit à New-York  # 1.8 

我用這個代碼：

use strict; 
use warnings; 
use Data::Dump; 

open(TEXT, "<", "$ARGV[0]") 
    or die "cannot open < $ARGV[0]: $!"; 

while(my $text = <TEXT>) 
{ 
    my @lines = split /\n/, $text; 

    foreach my $line (@lines) { 
     if ($line =~ /(^(.+)\t(.+)\t(.+)$)/){ 
      my $english_sentence = $2; 
      my $french_sentence = $3; 
      my $score = $4; 

      print $english_sentence."#".$french_sentence.""; 

      my @data = map [ split /;/ ], $line =~/\[ ([^\[\]]+) \] /xg; 
      dd \@data; 
     } 
     print "\n"; 
    } 
} 
close TEXT; 

這裏是輸出：

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins 
Array==>[["chats", "chaton", "chatterie"], ["lapins", "lapereau"]] 

My father [père;parent;papa] lives in New-York # Mon père vit à New-York 
Array==>[["père", "parent", "papa"]] 

我需要在此字符串刪除數組中的字符串與句子的一部分相匹配。最後，我想要得到這樣的結果：

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins 
[["chats"], ["lapins"]] 

My father [père;parent;papa] lives in New-York # Mon père vit à New-York 
[["père"]] 

Answer 1

這會照你的要求去做。它只是使用grep和一個正則表達式來將每個列表縮小爲僅出現在法語句子中的那些單詞。

use utf8; 
use strict; 
use warnings; 
use 5.010; 
use autodie; 

use open qw/ :std :encoding(UTF-8) /; 

use Data::Dump; 

open my $fh, '<', 'sentences.txt'; 

while (<$fh>) { 

    my @sentences = split /\s*#\s*/; 
    next unless @sentences == 3; 

    print join(' # ', @sentences[0,1]), "\n"; 

    my @data = map [ split /;/ ], $sentences[0] =~/\[ ([^\[\]]+) \] /xg; 
    $_ = [ grep { $sentences[1] =~ /\b\Q$_\E\b/ } @$_ ] for @data; 

    dd \@data; 
    print "\n"; 
} 

輸出

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins 
[["chats"], ["lapins"]] 

My father [père;parent;papa] lives in New-York # Mon père vit à New-York 
[["p\xE8re"]] 

---

更新

按照要求，該代碼將修改這些詞列表就地，使它們包含只出現的話在翻譯。

use utf8; 
use strict; 
use warnings; 
use 5.010; 
use autodie; 

use open qw/ :std :utf8 /; 

open my $fh, '<', 'sentences.txt'; 

while (<$fh>) { 

    my @sentences = split /\s*#\s*/; 
    next unless @sentences == 3; 

    print join(' # ', @sentences[0,1]), "\n"; 

    $sentences[0] =~ s{ \[ ([^\[\]]+) \] }{ 
    my @words = split /;/, $1; 
    @words = grep { $sentences[1] =~ /\b\Q$_\E\b/ } @words; 
    sprintf "[%s]", join ';', @words; 
    }exg; 

    print join(' # ', @sentences[0,1]), "\n\n"; 

} 

輸出

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins 
I love cat [chats] and rabbit [lapins] # J'aime les chats et les lapins 

My father [père;parent;papa] lives in New-York # Mon père vit à New-York 
My father [père] lives in New-York # Mon père vit à New-York 

Answer 2

您還可以通過創建的法文句子的單詞的哈希做到這一點。
這可能會更快，因爲它避免了第三個正則表達式。

use strict; 
use warnings; 

while (<DATA>) { 
    my ($English, $French, $repl, %FrWords); 
    if (($English, $French) = m/^([^#]*)\#([^#]*)\#/) { 
     @FrWords{ split /\h+/, $French } = undef; 
     $English =~ s{ \[ ([^\[\]]*) \] }{ 
       $repl = join(';', grep { exists $FrWords{$_} } split /;/, $1); 
       '['. (length($repl) ? $repl : '') .']'; 
      }xeg; 
     print $English, '#', $French, "\n"; 
    } 
} 
__DATA__ 

I love cat [chats;chaton;chatterie] and rabbit [lapins;lapereau] # J'aime les chats et les lapins # 2.8 
My father [père;parent;papa] lives in New-York # Mon père vit à New-York  # 1.8 

輸出

I love cat [chats] and rabbit [lapins] # J'aime les chats et les lapins 
My father [père] lives in New-York # Mon père vit à New-York