爲什麼XSL函數「ends-with」和「matches」都會引發錯誤？

Question

我正在轉換一些XML，將名爲alt-title的每個元素重命名爲Running_Head，前提是屬性alt-title-type等於「running-head」。

---

所以，下面的代碼是使用行 <xsl:when test="starts-with(@alt-title-type, 'running-head')">哪些工作正常。然而，當我將其更改爲以下任一：

• <xsl:when test="ends-with(@alt-title-type, 'running-head')">
• <xsl:when test="matches(@alt-title-type, 'running-head')">

...這個錯誤被拋出：

Error:XSLTProcessor::transformToXml() [xsltprocessor.transformtoxml]: xmlXPathCompiledEval: 2 objects left on the stack.

所以，似乎函數starts-with正在工作，其中ends-with和matches不是。

---

這裏是我的XSL，使用 starts-with，這似乎是正常工作：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output encoding="UTF-8" indent="yes" method="xml" /> 

    <!-- Running_Head --> 
    <xsl:template match="@*|node()"> 
     <xsl:choose> 

      <xsl:when test="starts-with(@alt-title-type, 'running-head')"> 
       <xsl:element name="Running_Head"> 
        <xsl:apply-templates select="@*|node()"/> 
       </xsl:element> 
      </xsl:when> 

      <xsl:otherwise> 
       <xsl:copy> 
        <xsl:apply-templates select="@*|node()"/> 
       </xsl:copy> 
      </xsl:otherwise> 

     </xsl:choose> 
    </xsl:template> <!-- end of Running_Head --> 

</xsl:stylesheet> 

...這裏被轉換的XML：

<root-node> 
    <alt-title alt-title-type="running-head"> 
     This is working 
    </alt-title> 
    <alt-title alt-title-type="asdfng-head"> 
     asdfasdf 
    </alt-title> 
    <alt-title> 
     asdfasdf 
    </alt-title> 
    <alt-title alt-title-type="running-head"> 
     This is also working 
    </alt-title> 
</root-node> 

我正在測試這個在http://xslt.online-toolz.com/tools/xslt-transformation.php和http://www.xsltcake.com/。

Answer 1

正如其他人所指出的，XSLT 1.0處理器不支持大多數XPath 2.0函數（如matches()和ends-with()）。

此外，在實現該電流要求變換並不需要在所有這些功能：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="alt-title[@alt-title-type='running-head']"> 
    <Running_Head> 
    <xsl:apply-templates select="@*|node()"/> 
    </Running_Head> 
</xsl:template> 
</xsl:stylesheet> 

當這個變換所提供的XML文檔施加：

<root-node> 
    <alt-title alt-title-type="running-head"> 
     This is working 
    </alt-title> 
    <alt-title alt-title-type="asdfng-head"> 
    asdfasdf 
    </alt-title> 
    <alt-title> 
    asdfasdf 
    </alt-title> 
    <alt-title alt-title-type="running-head"> 
    This is also working 
    </alt-title> 
</root-node> 

想要的，正確的生成是：

<root-node> 
    <Running_Head alt-title-type="running-head"> 
     This is working 
    </Running_Head> 
    <alt-title alt-title-type="asdfng-head"> 
    asdfasdf 
    </alt-title> 
    <alt-title> 
    asdfasdf 
    </alt-title> 
    <Running_Head alt-title-type="running-head"> 
    This is also working 
    </Running_Head> 
</root-node> 

說明：

正確使用的模板，匹配模式和的identity rule壓倒一切。

Answer 2

只有XPath 2.0具有matches和ends-with函數。

在XPath 1.0，ends-with必須寫

$suffix = substring($target, string-length($target) - string-length($suffix) + 1) 

它沒有正則表達式的功能，但也許

包含（$目標$子）

是你想要的，如果你有什麼沒有使用正則表達式元字符

Answer 3

您將模板聲明爲XSLT 1.0，但您使用的是2.0函數ends-with和matches。使用XSL 2.0處理器（或work around the missing functions），並將您的文檔聲明爲XSLT 2.0。

請注意，您收到的錯誤是由這些服務使用的XSL處理器的內部錯誤（它看起來像不能正確處理未定義的函數）。