如何在Perl中使用XML文件？

Question

我需要使用Perl腳本來獲取XML文件中給定名稱的節點的子節點數據值。 我正在使用XML::LibXML::Simple。

一個代碼片段如下：

my $booklist = XMLin(path); 

    foreach my $book (@{$booklist->{detail}}) { 
    print $book->{name} . "\n"; 
} 

和XML文件如下所示：

<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
<book> 
<detail label='label1' status='active' type='none'> 
<name>book1</name> 
</detail > 
<detail label='label2' status='active' type='none'> 
<name>book2</name> 
</detail > 
</book> 
</booklist> 

當我使用上面的代碼中，我得到了以下錯誤消息： 「不是一個ARRAY參考「

任何人都可以請幫助我嗎？

Answer 1

下面是在OP中使用的XML :: Simple解決方案。

use strict; 
use warnings; 
use XML::Simple; 

my $booklist = XMLin($ARGV[0], KeyAttr => [], ForceArray => qr/detail/); 

foreach my $book (@{$booklist->{book}->{detail}}) { 
    print $book->{name} . "\n"; 
} 

這裏重要的是片給予XMLin的選項，迫使「細節」子節點被表示爲陣列。

一個快速入門的XML ::簡單是CPAN文件： http://metacpan.org/pod/XML::Simple

Answer 2

當你寫：

@{ $booklist->{detail} } 

...你是說$書目 - > {}詳細返回數組引用，你想要Perl取消對它的引用到一個數組，即「@」 。

請勿使用<name>作爲標籤。 XML :: Simple很奇怪地解析。這裏有一個例子：

1）

<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
    <book> 
     <bname>book1</bname> 
    </book> 
    <book> 
     <bname>book2</bname> 
    </book> 
</booklist> 

use strict; 
use warnings; 
use 5.016; 

use XML::Simple; 
use Data::Dumper; 



my $booklist = XMLin('xml.xml'); 
print Dumper($booklist); 


--output:-- 

$VAR1 = { 
      'book' => [ 
        { 
         'bname' => 'book1' 
        }, 
        { 
         'bname' => 'book2' 
        } 
        ] 
     }; 

2）現在看看會發生什麼，當你使用一個<name>標籤：

<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
    <book> 
     <name>book1</bname> 
    </book> 
    <book> 
     <name>book2</bname> 
    </book> 
</booklist> 

--output:-- 
$VAR1 = { 
      'book' => { 
        'book2' => {}, 
        'book1' => {} 
        } 
     }; 

與你原來的例子

所以：

<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
    <book> 

    <detail label='label1' status='active' type='none'> 
     <bname>book1</bname> 
    </detail> 

    <detail label='label2' status='active' type='none'> 
     <bname>book2</bname> 
    </detail> 

    </book> 
</booklist> 


--output:-- 
$VAR1 = { 
      'book' => { 
        'detail' => [ 
           { 
            'bname' => 'book1', 
            'status' => 'active', 
            'label' => 'label1', 
            'type' => 'none' 
           }, 
           { 
            'bname' => 'book2', 
            'status' => 'active', 
            'label' => 'label2', 
            'type' => 'none' 
           } 
           ] 
        } 
     }; 

爲了得到所有的bname標籤，你可以這樣做：

use strict; 
use warnings; 
use 5.016; 

use XML::Simple; 
use Data::Dumper; 

my $booklist = XMLin('xml.xml'); 
my $aref = $booklist->{book}{detail}; 

for my $href (@$aref) { 
    say $href->{bname}; 
} 


--output:-- 
book1 
book2 

Answer 3

我覺得像這樣的....

use strict; 
use XML::Twig; 

my $text = join '', <DATA>; 
my $story_file = XML::Twig->new(
       twig_handlers =>{ 
       'name' => \&name, 
       keep_atts_order => 1, 
}, 
       pretty_print => 'indented', 
); 
$story_file->parse($text); 

sub name { 
     my ($stroy_file, $name) = @_; 
    print $name->text, "\n"; 
} 

__END__ 
<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
<book> 
<detail label='label1' status='active' type='none'> 
<name>book1</name> 
</detail > 
<detail label='label2' status='active' type='none'> 
<name>book2</name> 
</detail > 
</book> 
</booklist> 

Answer 4

從XML::Simple docs：

使用本模塊中新代碼是不鼓勵。其他模塊可提供更直接和一致的接口。尤其強烈建議使用XML :: LibXML。

該模塊的主要問題是大量的選項以及這些選項交互的任意方式 - 通常會帶來意想不到的結果。

無論如何。

在您的代碼中，您正在瀏覽書單中包含包含詳細信息的書籍的事實。該書目沒有直接的細節。下面是使用XML::LibXML短的解決方案：

use strict; use warnings; use 5.010; use XML::LibXML; 

my $dom = XML::LibXML->load_xml(IO => \*DATA) or die "Can't load"; 

for my $detail ($dom->findnodes('/booklist/book/detail')) { 
    say $detail->findvalue('./name'); 
} 

__DATA__ 
<?xml version='1.0' encoding='iso-8859-1'?> 
<booklist> 
    <book> 
    <detail label='label1' status='active' type='none'> 
     <name>book1</name> 
    </detail > 
    <detail label='label2' status='active' type='none'> 
     <name>book2</name> 
    </detail > 
    </book> 
</booklist> 

正如你可以在XPath表達式/booklist/book/detail看到的，我們首先要看看書發現的細節之前。當然，這可以縮短到//detail。

一般來說，如果一個數據結構不像它看起來那樣，那麼應該轉儲它，例如，

use Data::Dumper; 
print Dumper $booklist; 

這將輸出：

$VAR1 = { 
    'book' => { 
    'detail' => { 
     'book2' => { 
     'status' => 'active', 
     'type' => 'none', 
     'label' => 'label2' 
     }, 
     'book1' => { 
     'status' => 'active', 
     'type' => 'none', 
     'label' => 'label1' 
     } 
    } 
    } 
}; 

所以對一些性交的原因，book1和book2字符串現在是在一個嵌套的哈希鍵。幫你一個忙，並停止使用CPAN上最複雜的XML模塊，即「XML :: Simple」。

Answer 5

然而使用XML::Rules（假設的一點是要得到的東西在「細節」，而不是僅僅打印「名稱的內容另一種方式'）：

use XML::Rules; 
my @rules = (
    detail => sub { 
    print "$_[1]{name}\n"; 
    return; 
    }, 
    name => 'content', 
    _default => undef, 
); 

my $xr = XML::Rules->new(rules => \@rules); 
$xr->parsefile("tmp.xml");