sort_by函數如何工作？

Question

基於this的帖子，我想了解sort_by如何在JSON::PP中工作。

當運行該代碼

#!/usr/bin/perl 
use strict; 
use warnings; 
use JSON::PP; 
use Data::Dumper qw(Dumper); 

my $h = { 
    22 => { title => "c", name => "d" }, 
    1 => { title => "1", name => "a" }, 
    10 => { title => "a", name => "c" }, 
    5 => { title => "b", name => "b" }, 
}; 

my $sorter = sub { 
    # See what's going on. 
    print "$JSON::PP::a cmp $JSON::PP::b\n"; 
    print Dumper(\@_, $_); 
    <STDIN>; # press return to continue 

    $JSON::PP::a cmp $JSON::PP::b 
}; 

my $js = JSON::PP->new; 
my $output = $js->sort_by($sorter)->encode($h); 
print $output . "\n"; 

它第一排序的內密鑰，然後將外鍵，其確定在JSON字符串的最後順序。

現在它輸出

{"1":{"name":"a","title":"1"},"10":{"name":"c","title":"a"},"22":{"name":"d","title":"c"},"5":{"name":"b","title":"b"}} 

什麼，我想直到結束的是，它是由title即排序。

{"1":{"name":"a","title":"1"},"5":{"name":"b","title":"b"}"10",{"name":"c","title":"a"},"22":{"name":"d","title":"c"}} 

我想第一個問題是禁用最後一個outter鍵排序？

那麼我該如何獲得title的價值？算法運行時，$JSON::PP::a和$JSON::PP::b包含來自相同散列的值name和title。

這我想不通。任何人都可以解釋這一點，和/或幫我寫這個算法？

Answer 1

你不能，或者至少不容易。您給sort_by的功能只能訪問正在排序的鍵。爲了做你想做的事，你需要訪問與這些鍵相關的值（或者更可能的是，鍵所屬的hashref，以便你可以自己查找這些值）。這似乎是一個有益的增強;您可能會提交功能請求。

如果您的數據結構足夠簡單（您的示例似乎是），那麼您可以自己保留對散列的引用。爲了做到這一點，你必須能夠區分內部哈希中的鍵和外部哈希中的鍵（這樣你就知道哪個哈希正在被排序，從而進行什麼樣的比較）。

my $sorter = sub { 
    if ($JSON::PP::a =~ /^\d+$/) { 
     return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
    } 
    return $JSON::PP::a cmp $JSON::PP::b 
}; 

Answer 2

嘗試類似：

my $sorter = sub { 
    my $h = $_[0]; 

    # simple check for if we are too deep 
    # just sort by keys in that case 
    return $JSON::PP::a cmp $JSON::PP::b 
     if ref($h->{$JSON::PP::a}) ne 'HASH'; 

    # sort by titles value 
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
}; 

$_[0]目前正在整理散，本書雖然這似乎並沒有被記錄（因此可能是不可靠的）。

它適用於這種情況，但更復雜的結構會有問題，因爲深度檢查非常簡單。如果你確定不存在這種類型的更深的鍵，那麼對cjm這樣的鍵類型的檢查會更好。或者組合，如：

my $sorter = sub { 
    my $h = $_[0]; 

    # just sort by the keys 
    return $JSON::PP::a cmp $JSON::PP::b 
     unless $JSON::PP::a =~ /^\d+\z/ 
      && $JSON::PP::b =~ /^\d+\z/ 
      && ref($h->{$JSON::PP::a}) eq 'HASH' 
      && ref($h->{$JSON::PP::b}) eq 'HASH'; 

    # sort by titles 
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
};