通過Vlookup宏向相鄰目標範圍添加文本值

Question

下午好，我想借助Sheet1.Range（「I15：I18」）中改變的單元值宏函數 來引入基於Vlookup函數的文本值，避免使用公式。這是VLOOKUP函數文本看錶：

A  B 
1 0  Low Risk 
2 10 Medium Risk 
3 15 High Risk 

由此可見，它並沒有爲我工作的代碼：

Private Sub Worksheet_Change(ByVal Target As Range) 
    Dim KeyCells As Range 
    Dim num As Long 
    Dim sRes As Variant 

    Set KeyCells = Sheet1.Range("I15:I18") 

    If Not Application.Intersect(KeyCells, Range(Target.Address)) Is Nothing Then 
     sRes = Application.VLookup(num, Sheet2.Range("A56:B58"), 2, True) 

     Debug.Print sRes 
     Sheet1.Target.Offset(0, 1).Text = sRes 
    End If 
End Sub 

，在範圍落在實際得分是由觸發另一個宏，它完美的工作。 這裏也遵循與單細胞的工作原理好嗎宏：

Sub NumberVLookup() 
    Dim num As Long 
    num = 16 

    Dim sRes As Variant 
    sRes = Application.VLookup(num, Sheet2.Range("A56:B58"), 2, True) 

    Debug.Print sRes 
    Sheet2.Range("J15") = sRes 
End Sub 

我真的很感謝你在這方面的幫助。

Answer 1

未經測試：

Private Sub Worksheet_Change(ByVal Target As Range) 
    Dim rng As Range 
    Dim sRes As Variant 

    on error goto haveError 

    Set rng = Application.Intersect(Me.Range("I15:I18"), Target) 

    If Not rng Is Nothing Then 
     If rng.cells.count = 1 then 
      sRes = Application.VLookup(rng.Value, _ 
        Sheet2.Range("A56:B58"), 2, True) 
      'turn off events before updating the worksheet 
      Application.enableEvents = False 
      rng.Offset(0, 1).Value = IIf(IsError(sRes), "???", sRes) 
      Select Case rng.Offset(0, 1).Value 
       Case "Low Risk": rng.Offset(0, 2).Value = Date + 180 
       Case "Medium Risk": rng.Offset(0, 2).Value = Date + 150 
       Case "High Risk": rng.Offset(0, 2).Value = Date + 120 
      End Select 
      Application.enableEvents = True 
     End If '<< edit added missing line here 
    End If 
    Exit Sub 

haveError: 
    Application.enableEvents = True '<< ensures events are reset 
End Sub