ANTLR命題邏輯評估器

Question

我試圖在評估命題邏輯公式的ANTLR中創建一個語法。所以對於輸入(1 & 0) | 1，它應該返回true。

我已經構建了以下內容：

code returns[boolean value] 
    : formula EOF {$value = $formula.value;} 
    ; 

formula returns [boolean value] 
    : equiv {$value = $equiv.value;} 
    ; 

equiv returns [boolean value] 
    : a=implies {$value = $a.value;} 
    ('#' b=implies {$value = $value == $b.value;} 
)* 
    ; 

implies returns [boolean value] 
    : a=or {$value = $a.value;} 
    ('>' b=or {$value = !$value || $b.value;} 
)* 
    ; 

or returns [boolean value] 
    : a=and {$value = $a.value;} 
    ('|' b=and {$value ||= $b.value;} 
)* 
    ; 

and returns [boolean value] 
    : a=term {$value = $a.value;} 
    ('&' b=term {$value &&= $b.value;} 
)* 
    ; 

term returns [boolean value] 
    : '(' formula ')' {$value = $formula.value;} 
    | '0' {$value = false;} 
    | '1' {$value = true;} 
    | '¬' term {$value = !$term.value;} 
    ; 

WHITESPACE: (' '|'\t'|'\r'|'\f'|'\n')+{$channel = HIDDEN;} ; 

不過，我不斷收到錯誤java.lang.NoSuchFieldError的：offendingToken。無論如何要找出錯誤在哪裏或如何解決？

Answer 1

有3個問題：

• {$value ||= $b.value;}應該{$value = $value || $b.value;}
• {$value &&= $b.value;}應該{$value = $value && $b.value;}
• 在term規則的第四替代標籤$term是不明確的：是可以參考的規則本身，或者term後面跟着'¬'

即，以下：

term returns [boolean value] 
    : ... 
    | '¬' term {$value = !$term.value;} 
    ; 

應該是：

term returns [boolean value] 
    : ... 
    | '¬' t=term {$value = !$t.value;} 
    ; 

在作出這些改變，下面的測試類：

import org.antlr.runtime.*; 

public class Main { 
    public static void main(String[] args) throws Exception { 
    String source = "(1 & 0) | 1"; 
    TestLexer lexer = new TestLexer(new ANTLRStringStream(source)); 
    TestParser parser = new TestParser(new CommonTokenStream(lexer)); 
    System.out.println(source + " = " + parser.code()); 
    } 
} 

產生所需的輸出：

java -cp antlr-3.3.jar org.antlr.Tool Test.g 
javac -cp antlr-3.3.jar *.java 
java -cp .:antlr-3.3.jar Main 

(1 & 0) | 1 = true