如何檢查變量是否包含批處理文件中的特殊字符

如何檢查批處理文件中的變量是否包含特殊字符？例如，如果我的變量包含文件名，那麼文件名不應該包含這些字符，如\/ < > | : * " ?。如何檢查變量是否包含批處理文件中的特殊字符

@echo off 
set param="XXX" 
echo %param%| findstr /r "^[^\\/?%*:|"<>\.]*$">nul 

if %errorlevel% equ 0 goto :next 
echo "Invalid Attribute" 

:next 
echo correct

我用這個鏈接作爲參考regex for validating folder name & file name

來源

2015-11-09 acer

到目前爲止您嘗試過什麼？請編輯您的文章分享你的企圖... – aschipfl

其實我沒有任何想法，我可以使用正則表達式這裏 – acer

對不起，它的Windows – acer

不能使用echo %param%| findstr /r ...甚至也不是echo !param!| findstr /r ...。有關管道如何分析和處理的更多信息，請看這個問題和答案：Why does delayed expansion fail when inside a piped block of code。

使用的輔助（臨時）文件，如下所示：

@ECHO OFF 
SETLOCAL EnableExtensions EnableDelayedExpansion 
:testloop 
    set "param=" 
    set /P "param=string to test (hit <Enter> to end)> " 
    if not defined param goto :endtest 
    >"%temp%\33605517.txt" echo(!param! 

    rem next line for debugging purposes 
    for /F "usebackq delims=" %%G in ("%temp%\33605517.txt") do set "_marap=%%G" 

    findstr /r ".*[<>:\"\"/\\|?*%%].*" "%temp%\33605517.txt" >nul 

    if %errorlevel% equ 0 (
    echo !errorlevel! Invalid !param! [!_marap!] 
) else (
    echo !errorlevel! correct !param! [!_marap!] 
) 
    goto :testloop 
:endtest 
ENDLOCAL 
goto :eof

.*[<>:\"\"/\\|?*%%].*正則表達式解釋：

.* - 在一個字符串的前面的任何字符的零次或多個出現次數;
[<>:\"\"/\\|?*%%]在組保留字符的任一個字符：
- <（小於）;
- >（大於）;
- :（colon）;
- "（雙引號）轉義爲\"\"（findstr和批解析器）;
- /（正斜槓）;
- \（反斜槓）轉義爲\\（findstr）;
- |（豎條或管）;
- ?（問號）;
- *（星號）;
- %（百分號）轉義（對於批解析器）爲%%;實際上，% is not reserved for NTFS file system但需要在純cmd和/或批處理腳本中進行特殊轉義;
.* - 零個或多個出現在字符串末尾的任何字符。

這裏有更多的關於SO的一些問題的鏈接，包括Aacini，DBenham，Jeb（其他人）的詳盡答案。引人入勝，迷人的閱讀......

輸出：

string to test (hit <Enter> to end)> n<m 
0 Invalid n<m [n<m] 
string to test (hit <Enter> to end)> n>m 
0 Invalid n>m [n>m] 
string to test (hit <Enter> to end)> n:m 
0 Invalid n:m [n:m] 
string to test (hit <Enter> to end)> n/m 
0 Invalid n/m [n/m] 
string to test (hit <Enter> to end)> n\m 
0 Invalid n\m [n\m] 
string to test (hit <Enter> to end)> n|m 
0 Invalid n|m [n|m] 
string to test (hit <Enter> to end)> n?m 
0 Invalid n?m [n?m] 
string to test (hit <Enter> to end)> n*m 
0 Invalid n*m [n*m] 
string to test (hit <Enter> to end)> n"m 
0 Invalid n"m [n"m] 
string to test (hit <Enter> to end)> nm 
1 correct nm [nm] 
string to test (hit <Enter> to end)> nm.gat 
1 correct nm.gat [nm.gat] 
string to test (hit <Enter> to end)> n%m.gat 
0 Invalid n%m.gat [n%m.gat] 
string to test (hit <Enter> to end)>

來源

2015-11-10 08:04:17 JosefZ

非常感謝，你的答案是完美的，明確的，工作對我來說 – acer

很好的解決方案，並解釋小評你的鏈接[如何命令行參數解析（HTTP：。//www.daviddeley。 com/autohotkey/parameters/parameters.htm）。說明如何轉義命令li ne參數（對於windows）是錯誤的，通常它會起作用，但使用三個插入符仍然不正確。 – jeb

您可以FINDSTR線改爲

set "param=Test < string" 

cmd /v:on /c echo(^^!param^^! | findstr /r "^[^\\/?%%*:|<>\.\"]*$^" > nul 

if %errorlevel% equ 0 ( 
echo OK 
) ELSE (
    echo Invalid, special character found 
)

這工作，因爲帕拉姆將與延遲擴展孩子的cmd.exe進程進行擴展。
如果啓用了延時擴展或延時擴展功能，則該線路一直工作並不重要。
我改變了正則表達式，至於搜索引用本身有點討厭。

來源

2015-11-10 09:24:04 jeb

它也工作正常，謝謝 – acer

我看不出有什麼問題，用'設置測試「參數= 123abcd <」' – jeb

請使用''％（百分號）增加了一倍。否則，'a * b'結果爲OK。 – JosefZ

如何檢查變量是否包含批處理文件中的特殊字符

回答

相關問題