如何檢查變量是否包含Windows批處理文件中的其他變量？

Question

假設下面的批處理文件

set variable1=this is variable1 
set variable2=is 
set variable3=test 

if variable1 contains variable2 (
    echo YES 
) else (
    echo NO 
) 

if variable1 contains variable3 (
    echo YES 
) else (
    echo NO 
) 

我想成爲一個YES，隨後按一個NO

Answer 1

輸出，我用下面的

setLocal EnableDelayedExpansion 

set variable1=this is variable1 
set variable2=is 
set variable3=test 

if not "x!variable1:%variable2%=!"=="x%variable1%" (
    echo YES 
) else (
    echo NO 
) 

if not "x!variable1:%variable3%=!"=="x%variable1%" (
    echo YES 
) else (
    echo NO 
) 

endlocal 

解決了這個給我的基本思路從下面的答案，但它不是由一個變量搜索，所以它不完全是我正在尋找。

Batch file: Find if substring is in string (not in a file)

Answer 2

另一種方式：

echo/%variable1%|find "%variable2%" >nul 
if %errorlevel% == 0 (echo yes) else (echo no) 

的/防止Echo is ON或Echo is OFF輸出的情況下%variable1%是空的。

Answer 3

加里布倫頓的答案不適合我。

如果用set variable1="C:\Users\My Name\"嘗試，你將最終獲得一個錯誤：

'Name\""' is not recognized as an internal or external command 

適應這個答案Find out whether an environment variable contains a substring，我結束了：

echo.%variable1%|findstr /C:"%variable2%" >nul 2>&1 
if not errorlevel 1 (
    echo Found 
) else (
    echo Not found 
)