SQL Server：獲取提出錯誤的查詢

Question

當我使用usp_RethrowError（作爲Using TRY...CATCH in Transact-SQL文章technet.microsoft站點中的示例給出的示例）時，發出信號有問題。

有沒有什麼辦法讓這觸發usp_RethrowError過程內這個錯誤的查詢？我還想將查詢文本添加到@ErrorMessage。

你可以找到usp_RethrowError存儲過程的代碼如下：

CREATE PROCEDURE usp_RethrowError AS 
    -- Return if there is no error information to retrieve. 
    IF ERROR_NUMBER() IS NULL 
     RETURN; 

    DECLARE 
     @ErrorMessage NVARCHAR(4000), 
     @ErrorNumber  INT, 
     @ErrorSeverity INT, 
     @ErrorState  INT, 
     @ErrorLine  INT, 
     @ErrorProcedure NVARCHAR(200); 

    -- Assign variables to error-handling functions that 
    -- capture information for RAISERROR. 
    SELECT 
     @ErrorNumber = ERROR_NUMBER(), 
     @ErrorSeverity = ERROR_SEVERITY(), 
     @ErrorState = ERROR_STATE(), 
     @ErrorLine = ERROR_LINE(), 
     @ErrorProcedure = ISNULL(ERROR_PROCEDURE(), '-'); 

    -- Build the message string that will contain original 
    -- error information. 
    SELECT @ErrorMessage = 
     N'Error %d, Level %d, State %d, Procedure %s, Line %d, ' + 
      'Message: '+ ERROR_MESSAGE(); 

    -- Raise an error: msg_str parameter of RAISERROR will contain 
    -- the original error information. 
    RAISERROR 
     (
     @ErrorMessage, 
     @ErrorSeverity, 
     1,    
     @ErrorNumber, -- parameter: original error number. 
     @ErrorSeverity, -- parameter: original error severity. 
     @ErrorState,  -- parameter: original error state. 
     @ErrorProcedure, -- parameter: original error procedure name. 
     @ErrorLine  -- parameter: original error line number. 
     ); 
GO 

Answer 1

不幸的是動態管理視圖仍然使它在這個信息讓困難的，因爲它們存儲SQL_TEXT的程序，而不是用戶實際做了。但是，在這種情況下，DBCC仍然是你的朋友。不是世界上最有效率的東西，但它會找出用戶輸入的內容（而不是程序中的語句），但是這可以揭示錯誤發生時正在使用哪些參數？

ALTER PROCEDURE dbo.usp_RethrowError 
AS 
BEGIN 
    SET NOCOUNT ON; 

    -- Return if there is no error information to retrieve. 
    IF ERROR_NUMBER() IS NULL 
     RETURN; 

    DECLARE 
     @ErrorMessage NVARCHAR(MAX), 
     @ErrorNumber  INT, 
     @ErrorSeverity INT, 
     @ErrorState  INT, 
     @ErrorLine  INT, 
     @ErrorProcedure NVARCHAR(200); 

    -- Assign variables to error-handling functions that 
    -- capture information for RAISERROR. 
    SELECT 
     @ErrorNumber = ERROR_NUMBER(), 
     @ErrorSeverity = ERROR_SEVERITY(), 
     @ErrorState = ERROR_STATE(), 
     @ErrorLine = ERROR_LINE(), 
     @ErrorProcedure = ISNULL(ERROR_PROCEDURE(), '-'); 

    -- Build the message string that will contain original 
    -- error information. 
    SELECT @ErrorMessage = 
     N'Error %d, Level %d, State %d, Procedure %s, Line %d, ' + 
      'Message: '+ ERROR_MESSAGE(); 

    DECLARE 
     @sql NVARCHAR(255), 
     @original_statement NVARCHAR(MAX); 

    SET @sql = N'DBCC INPUTBUFFER(' + RTRIM(@@SPID) + ');'; 

    CREATE TABLE #dbcc 
    (
     EventType SYSNAME, 
     Parameters INT, 
     EventInfo NVARCHAR(MAX) 
    ); 

    INSERT #DBCC EXEC(@sql); 

    SELECT TOP 1 @original_statement = EventInfo 
     FROM #dbcc; 

    SET @ErrorMessage = @ErrorMessage + N' 
     Original statement: 
     ' + @original_statement + ' 
     '; 

    -- Raise an error: msg_str parameter of RAISERROR will contain 
    -- the original error information. 
    RAISERROR 
     (
     @ErrorMessage, 
     @ErrorSeverity, 
     1,    
     @ErrorNumber, -- parameter: original error number. 
     @ErrorSeverity, -- parameter: original error severity. 
     @ErrorState,  -- parameter: original error state. 
     @ErrorProcedure, -- parameter: original error procedure name. 
     @ErrorLine  -- parameter: original error line number. 
     ); 
END 
GO