解決多參數類型類的模糊實例

Question

我正在開發一個專門的數值數據處理庫，並且遇到了一個我無法弄清楚如何解決的錯誤。我認爲首先展示一個例子並解釋我的問題會更容易。我也爲奇怪的名字表示歉意，爲了合法目的我不得不混淆視聽。

{-# LANGUAGE MultiParamTypeClasses #-} 
{-# LANGUAGE FlexibleInstances  #-} 

data MyError = MyError String deriving (Eq, Show) 

data MyList = MyList [Double] deriving (Eq, Show) 
data NamedList = NamedList String MyList deriving (Eq, Show) 

class MyNum a b ret where 
    myAdd  :: a -> b -> Either MyError ret 
    myLessThan :: a -> b -> Either MyError Bool 

instance MyNum MyList Double MyList where 
    myAdd (MyList xs) x = Right $ MyList $ map (+x) xs 
    myLessThan (MyList xs) x = Right $ all (< x) xs 

instance MyNum NamedList Double NamedList where 
    myAdd (NamedList n l) x = fmap (NamedList n) $ myAdd l x 
    myLessThan (NamedList n l) x = myLessThan l x 

如果我嘗試編譯，我得到了錯誤

No instance for (MyNum MyList Double ret0) 
    arising from a use of `myLessThan' 
The type variable `ret0' is ambiguous 
Possible fix: add a type signature that fixes these type variable(s) 
Note: there is a potential instance available: 
    instance MyNum MyList Double MyList 
    -- Defined at testing_instances.hs:13:10 
Possible fix: 
    add an instance declaration for (MyNum MyList Double ret0) 
In the expression: myLessThan l x 
In an equation for `myLessThan': 
    myLessThan (NamedList n l) x = myLessThan l x 
In the instance declaration for `MyNum NamedList Double NamedList' 

因爲編譯器無法弄清楚用於MyList其中MyNum具體實例。它適用於myAdd，因爲MyNum的返回類型很容易推導出來，但無法找出myLessThan。我想使用這個類型類型，以便我可以輕鬆地添加細粒度的錯誤處理，並且因爲我的實際代碼具有等效於+， - ，*，/，<，< =，>和> =，我想要爲MyNum Double MyList MyList，MyNum MyList MyList MyList和NamedList做出類似的實例。除非有更簡單的方法來做到這一點，否則我可以擁有多態交換操作符。

但是，我不知道什麼類型的簽名添加到第二個實例myLessThan，以便它可以知道使用哪個實例。我知道一種解決方案是將算術和比較運算符分爲兩個單獨的類型類，但是我想盡可能避免這樣做。

Answer 1

您可以使用functional dependencies來指定「ret由a和b唯一確定」。

... 
{-# LANGUAGE FunctionalDependencies #-} 
... 
class MyNum a b ret | a b -> ret where 
... 

這讓typechecker知道，它可以選擇正確的實例定義，只知道從參數中a和b您：

myLessThan (NamedList n l) x = myLessThan l x 

，如果你定義一個額外的編譯器現在抱怨實例具有相同a和b但不同ret，如

instance MyNum MyList Double SomeOtherType where 

Answer 2

正如jberryman指出的，你可以使用TypeFamilies。這該是多麼：

-{-# LANGUAGE FlexibleInstances  #-} 
+{-# LANGUAGE TypeFamilies #-} 

-class MyNum a b ret where 
- myAdd  :: a -> b -> Either MyError ret 
+class MyNum a b where 
+ type Ret a b 
+ myAdd  :: a -> b -> Either MyError (Ret a b) 

-instance MyNum MyList Double MyList where 
+instance MyNum MyList Double where 
+ type Ret MyList Double = MyList 

-instance MyNum NamedList Double NamedList where 
+instance MyNum NamedList Double where 
+ type Ret NamedList Double = NamedList 

我剛剛搬到從類參數ret類型associated typeRet。
這是一個TypeFamily - 通過說明從類參數a和b到Ret有功能。