在VBA中處理一系列逗號分隔值

Question

我有這個函數，它以字符串的形式返回逗號分隔的字符串中的值，該字符串按照給定的整數值的順序。

Private Sub TestGetNthNumber() 
    Debug.Print GetNthNumber("NUMBERS 5088, 5089, 5090, 5091", 2) 
End Sub 

Public Function GetNthNumber(sMark As String, iOrder As Integer) As String 
    Dim sTemp As String 
    Dim sNumber As String 
    Dim iLoop As Integer 

    If sMark = "" Then 
     Exit Function 
    End If 

    sTemp = sMark & "," 

    For iLoop = 1 To iOrder 
     sTemp = Mid(sTemp, InStr(sTemp, " ")) 
     sNumber = Trim(Left(sTemp, InStr(sTemp, ",") - 1)) 
     sTemp = Mid(sTemp, InStr(sTemp, ",") + 1) 
    Next 

    GetNthNumber = sNumber 
End Function 

測試小組將在值的列表中返回"5089"作爲其給定數量的2。

我的問題; 有沒有更好的方法來做到這一點，而不是Mid，Left和InStr的混亂字符串操作？像將逗號分隔的字符串值轉換爲數組的方式一樣？

另一個問題; 字符串格式爲"NUMBERS 5088, 5089, 5090 and 5091"。但爲此，我假設在處理它之前只需用替換","就可以了。

Answer 1

另一種方法是使用正則表達式/正則表達式。你的函數將看起來像這樣：

Public Function GetNthNumberAlternative(sMark As String, iOrder As Integer) As String 

    'regexp declaration 
    Dim objRegExp As Object 
    Set objRegExp = CreateObject("vbscript.regexp") 

    With objRegExp 
     .Global = True 
     .Pattern = "\d+" 

     GetNthNumberAlternative = .Execute(sMark)(iOrder - 1).Value 
    End With 

End Function 

而且你可以把它用這種方式：

Private Sub TestGetNthNumber() 
    Debug.Print GetNthNumberAlternative("NUMBERS 5088 AND 5089 OR 5090, 5091", 1) 
End Sub 

Answer 2

您想使用Split函數。如果每次都有相同的值，則可以刪除NUMBERS和最終的AND。事情是這樣的：

Private Sub TestGetNthNumber() 
    Debug.Print GetNthNumber("NUMBERS 5088, 5089, 5090, 5091", 2) 
End Sub 

Public Function GetNthNumber(sMark As String, iOrder As Integer) As String 
    Dim vArray As Variant 

    sMark = Replace(sMark, "NUMBERS", "") 
    sMark = Replace(sMark, "AND", "") 
    vArray = Split(sMark, ",") 

    GetNthNumber = vArray(iOrder) 

End Function