參數輸入的參數陣列問題

Question

所以我一直在試圖創建一個函數來將VBA中的分貝加在一起。我試過使用ParamArray，但我在處理信息時遇到了麻煩。理想情況下，它可以像SUM（）一樣工作，只需要把所有的投入都投入公式和繁榮。

現在，我有：

Function DBADD3(ParamArray nums()) As Double 
Dim DBPrTot As Variant 
'this will be input into the log function at the end 

DBPrTot = 0 
'initializing value for use in for loop 
For i = LBound(nums) To UBound(nums) 
    DBPrTot = DBPrTot + 10^(nums(i)/10) 
    'all of the values gathered from ParamArray are being input into this running total 

Next i 

DBADD3 = 10 * WorksheetFunction.Log10(DBPrTot) 
'throwing the DBPrTot running value into our end equation 

End Function 

我想它採取像DBADD3（A1：A3，A5，A7）的輸入，仍然生產的東西。有人可以幫忙嗎？

Answer 1

因此，您需要了解正在傳入的信息的類型。在之前的其他帖子的示例中，數字被直接傳入，因此可以輕鬆訪問它們的值。在這種情況下，您傳入一組範圍（範圍和單個單元格組）。所以你必須循環遍歷每個數組以拉取範圍組，然後循環遍歷範圍以獲取單個值。

請參閱以下基本SUM風格函數的例子：

Function ReturnValues(ParamArray args()) As Double 
    Dim dRunningTotal As Double 

    dRunningTotal = 0 

    For i = LBound(args) To UBound(args) 
     For Each cel In args(i) 
      dRunningTotal = dRunningTotal + cel.Value 
     Next cel 
    Next i 

    ReturnValues = dRunningTotal 
End Function 

編輯補充： 可以測試參數的類型，這樣就可以防止引發錯誤，並且還要處理情況下，您可能有兩個範圍和值的參數，即=ReturnValues(A1:A10, 7, 9, B1:B4)

Function ReturnValues(ParamArray args()) As Double 
    Dim dRunningTotal As Double 

    dRunningTotal = 0 

    For i = LBound(args) To UBound(args) 
     If TypeName(args(i)) = "Range" Then 
      For Each cel In args(i) 
       dRunningTotal = dRunningTotal + cel.Value 
      Next cel 
     Else 
      dRunningTotal = dRunningTotal + args(i) 
     End If 
    Next i 

    ReturnValues = dRunningTotal 
End Function