從計劃中的列表追加數字

Question

我目前正在學習計劃，並且遇到了一個示例問題。 以列表作爲輸入將每個元素轉換爲數字的一個數字，而列表以倒序排列。例如 （4 2 0 1）=> 1024，（3 9 9）=> 993等

我已經基本構建體：

(define dlnat-to-nat 
    (lambda (d) 
    (cond 
     ((null? d) 0) 
     ((not (list? d)) (error "No list given in parameters" d)) 
     ((append (car d) (if (not (null? (cdr d))) 
          (dlnat-to-nat (cdr d)) 
          '())))))) 

我試圖用（附加）和不在這種情況下不工作，我不知道有任何替代方式將數字附加爲數字？

Answer 1

不能使用列表操作爲建設一個數作爲輸出，append是附加列表，而不是數字。使用基本的算術運算來代替：

(define dlnat-to-nat 
    (lambda (d) 
    (cond ((or (null? d) (not (list? d))) 
      (error "Invalid input:" d)) 
      ((null? (cdr d)) 
      (car d)) 
      (else 
      (+ (car d) (* 10 (dlnat-to-nat (cdr d)))))))) 

更有效的解決方案將使用尾遞歸：

(define dlnat-to-nat 
    (lambda (d) 
    (if (or (null? d) (not (list? d))) 
     (error "Invalid input:" d) 
     (let loop ((lst (reverse d)) (acc 0)) 
      (if (null? lst) 
       acc 
       (loop (cdr lst) (+ (car lst) (* 10 acc)))))))) 

和更地道的實施將使用高階程序：

(define dlnat-to-nat 
    (lambda (d) 
    (if (or (null? d) (not (list? d))) 
     (error "Invalid input:" d) 
     (foldr (lambda (e acc) (+ e (* 10 acc))) 0 d)))) 

挑最適合您的需求！