將近似的多個匹配返回給組合框

Question

我想從列中返回多個匹配到組合框。所以，如果我有這樣的命名一列「變量：和搜索‘變量1’

然後我想在ComboBox這樣的輸出。如果沒有發現匹配，那麼‘不匹配’。

Answer 1

我會用這樣的假設「近似匹配」是：a）不區分大小寫，和b）只需要搜索字符串是Range值內某處試試這個代碼UserForm內：

Option Explicit 

Private Sub CommandButton1_Click() 

    Dim rngSource As Range 
    Dim rngCell As Range 
    Dim strValueToApproximatelyMatch As String 
    Dim lngCounter As Long 
    Dim lngResultCount As Long 

    'get candidate values and put to an array 
    Set rngSource = Sheet1.Range("A2:A10") 

    'get value to match approximately 
    strValueToApproximatelyMatch = Me.TextBox1.Value 

    'clear combo box 
    Me.ComboBox1.Clear 

    'set result count to 0 
    lngResultCount = 0 

    'iterate array and look for approximate match to input 
    For lngCounter = 1 To rngSource.Rows.Count 
     'get candidate 
     Set rngCell = rngSource.Cells(lngCounter, 1) 
     'test candidate against value to approximately match 
     If InStr(1, rngCell.Value, strValueToApproximatelyMatch, vbTextCompare) > 0 Then 
      'add to list if test passed 
      Me.ComboBox1.AddItem rngCell.Value 
      'increment result count 
      lngResultCount = lngResultCount + 1 
     End If 
    Next lngCounter 

    'add the no match if result count =0 
    If lngResultCount = 0 Then 
     Me.ComboBox1.AddItem "No Match" 
    End If 

End Sub 

這是輸出我得到：