Adob​​e AIR - 將圖像保存到硬盤驅動器

Question

我發現下面的代碼片段將圖像保存到Adobe AIR的特定文件夾中。

如何修改它首次出現的"Save As" OS窗口？ （因此用戶可以選擇將圖像保存在硬盤上的位置）

var arrBytes:ByteArray = PNGEncoder.encode(bmd); 
    var file:File = File.desktopDirectory.resolvePath(folderName + "/" + fileName + fileNum + ".png"); 
    var fileStream:FileStream = new FileStream(); 
    // 
    fileStream.open(file, FileMode.WRITE); 
    fileStream.writeBytes(arrBytes); 
    fileStream.close(); 

謝謝。

Answer 1

使用File.browseForSave：

import flash.filesystem.*; 
import flash.events.Event; 
import flash.utils.ByteArray; 

var imgBytes:ByteArray = PNGEncoder.encode(bmd); 
var docsDir:File = File.documentsDirectory; 
try 
{ 
    docsDir.browseForSave("Save As"); 
    docsDir.addEventListener(Event.SELECT, saveData); 
} 
catch (error:Error) 
{ 
    trace("Failed:", error.message); 
} 

function saveData(event:Event):void 
{ 
    var newFile:File = event.target as File; 
    if (!newFile.exists) // remove this 'if' if overwrite is OK. 
    { 
     var stream:FileStream = new FileStream(); 
     stream.open(newFile, FileMode.WRITE); 
     stream.writeBytes(imgBytes); 
     stream.close(); 
    } 
    else trace('Selected path already exists.'); 
} 

的manual永遠是你的朋友:)

BTW，我看你是相對較新的位置 - 歡迎StackExchange！如果您發現我的答案有幫助，請務必將其選爲答案。