如何從Perl中的MediaWiki :: API中提取重定向標題列表？

Question

我試圖使用MediaWiki API從某個維基百科標題獲取所有重定向，我想我幾乎在那裏，但我迷失在散列和數組的複雜數據結構中。

如何提取重定向標題列表？

在我詢問「日本」，應該得到看起來像這樣的列表，例如：

'JPN',"Land der aufgehenden Sonne","Das Land der aufgehenden 
Sonne","Zipango","\x{65e5}\x{672c}","R\x{ec}b\x{11b}n" 

（側面的問題：爲什麼我沒有得到UTF-8字符串的所有情況）

以下代碼由MediaWiki::API文檔改編而來。

use MediaWiki::API; 
use warnings; 
binmode STDOUT, ':utf8'; 
use JSON; 
use Data::Dumper; 

my $LANG="de"; 

my $mw = MediaWiki::API->new({ api_url => 'https://en.wikipedia.org/w/api.php' } ); 
my $mw_LANG = MediaWiki::API->new({ api_url => "https://$LANG.wikipedia.org/w/api.php" } ); 

my $wikititle ="Japan"; 

my $alltitles = $mw_LANG->api({ 
action => 'query', 
titles => $wikititle, 
prop => 'redirects', 
format => 'json', 
}) 
|| die $mw_LANG->{error}->{code} . ': ' . $mw_LANG->{error}->{details}; 

#just print to know how the structure looks like 
print Dumper($alltitles); 

my ($pageid,$langlinks) = each (%{ $alltitles->{query}->{pages} }); 
print "pageid $pageid\n";#yes works: this prints the page id 

問題：如何獲得redirect-array中的實際標題？

my $relinks = $alltitles->{'query'}->{'pages'}->{$pageid}->{'redirects'}; #no does not work! 

    foreach my $el (@{ $relinks->{'title'} }) { 
    print " $el $el->{'*'}\n"; 
    } 

Answer 1

該查詢返回一個hashref。其中一個條目是query，它指向另一個包含pages的hashref。 pages hashref包含頁面id的鍵。其中每個指向另一個hashref，其中包含重定向條目，該條目是對包含此頁面重定向到的所有頁面的數組的引用。

把所有這些在一起：

#!/usr/bin/env perl 

use strict; 
use warnings; 

use open qw(:std :utf8); 

use MediaWiki::API; 
use JSON::MaybeXS; 
use Data::Dumper; 

my $LANG= "de"; 

my $mw = MediaWiki::API->new({ api_url => 'https://en.wikipedia.org/w/api.php' } ); 
my $mw_LANG = MediaWiki::API->new({ api_url => "https://$LANG.wikipedia.org/w/api.php" } ); 

my $wikititle ="Japan"; 

my $alltitles = $mw_LANG->api({ 
     action => 'query', 
     titles => $wikititle, 
     prop => 'redirects', 
     format => 'json', 
    } 
) or die sprintf '%d: %s', @{ $mw_LANG->{error} }{qw(code details)}; 

for my $pageid (keys %{ $alltitles->{query}{pages} }) { 
    my $r = $alltitles->{query}{pages}{$pageid}; 
    printf "Redirects for page %d with title '%s'\n", @{$r}{qw(pageid title)}; 
    for my $redirect (@{ $r->{redirects} }) { 
     printf "\t%d: '%s'\n", @{$redirect}{qw(pageid title)}; 
    } 
} 

Postfix dereferencing使事情有點清潔：

for my $pageid (keys $alltitles->{query}{pages}->%*) { 
    my $r = $alltitles->{query}{pages}{$pageid}; 
    printf "Redirects for page %d with title '%s'\n", $r->@{qw(pageid title)}; 
    for my $redirect ($r->{redirects}->@*) { 
     printf "\t%d: '%s'\n", $redirect->@{qw(pageid title)}; 
    } 
} 

這需要perl 5.20或更高版本。