Minizinc「var set of int：x」，而不是「set of int：x」

Question

我在Golfers問題中設置了一組數組（每週都應該組成一個組，一次，每個人都確切地扮演着每星期一次）：

int: gr; %number of groups 
set of int: G=1..gr; 
int: sz; %size of groups 
set of int: S=1..sz; 
int: n=gr*sz; %number of players 
set of int: P=1..n; 
int: we; % number of weeks 
set of int: W=1..we; 

include "globals.mzn"; 

array[G,W] of var set of P: X; %X[g,w] is the set of people that form group g in week w 

我的約束如下（我不知道，如果一切正常，尚未）：

constraint forall (g in G, w in W) (card (X[g,w]) = sz); %Each group should have size sz 

constraint forall (w in W, g,h in G where g > h) (disjoint(X[g,w], X[h,w])); % Nobody plays twice in one week 

constraint forall (w,u in W where w > u) (forall (g,h in G) (card(X[g,w] intersect X[h,u]) <= 1)); % Two players never meet more than once 

constraint forall (w in 2..we) (w+sz-1 in X[1,w] /\ 1 in X[1,w]); %Symmetries breaking: week permutations 

constraint forall (w in W, g in 1..gr-1) (min(X[g,w]) < min(X[g+1,w])); %Symmetries breaking: group permutations 

constraint forall (g in G, s in S) (s+sz*(g-1) in X[g,1]); 

solve satisfy; 

output [ show(X[i,j]) ++ if j == we then "\n" else " " endif | i in 1..gr, j in 1..we ]; 

我的問題在於限制數量5.我不能在「var set of int：x」上使用min，我應該在「set of int：x」上使用它。不幸的是，我不明白這兩者之間的區別（從我讀過的內容來看，這可能與定義每組的大小有關，但我不確定）。

有人可以向我解釋這個問題並提出解決方案嗎？我會非常感激。謝謝！

Answer 1

我已經找到了解決方案 - 在這種情況下，我們應該創建一組元素來使max函數成爲可能。

constraint forall (w in 2..we) (max([i | i in X[1,w-1]]) < max([i | i in X[1,w]])); %Symmetries breaking: week permutations 

constraint forall (w in W, g in 1..gr-1) (min([i | i in X[g,w]]) < min([i | i in X[g+1,w]]));% Symmetries breaking: group permutations (I have been trying to speed up the constraint above, but it does not work with var set of int..) 

Answer 2

首先：A var是一個決策變量。所有Minizinc計劃的目標都是確定所有決策變量的價值。你不知道這些值是什麼，你正試圖找到這些值。任何不是var的只是一個已知的數字。 （不考慮使用集合）

在Minizinc中並未實現決策變量（var）的min(X[g,w])。原因將是使用X[g,w] < X[g+1,w]沒有最小值更有意義。爲什麼只限制所有數字中的最低數字。即{1,3,5} {< 1,4} insted的的1 < 1

（我希望MiniZinc對套<，所以我不會說謊，我不知道）