如何獲取文件名而不是打開文件的整個文件路徑？

Question

換句話說，我需要在調用Application.GetOpenFileName()方法之後做一些字符串處理嗎？

Answer 1

我正在使用這些函數進行文件名處理。最後一個是你需要的一個。

Public Function FilePathOf(ByVal s As String) As String 
    Dim pos As Integer 

    pos = InStrRev(s, "\") 
    If pos = 0 Then 
     FilePathOf = "" 
    Else 
     FilePathOf = Left$(s, pos) 
    End If 
End Function 

Public Function FileNameOf(ByVal s As String) As String 
    Dim pos1 As Integer, pos2 As Integer 

    pos1 = InStrRev(s, "\") + 1 
    pos2 = InStrRev(s, ".") 
    If pos2 = Len(s) Then pos2 = pos2 + 1 
    If pos2 = 0 Then pos2 = Len(s) + 1 
    FileNameOf = Mid$(s, pos1, pos2 - pos1) 
End Function 

Public Function FileExtOf(ByVal s As String) As String 
    Dim pos As Integer 

    pos = InStrRev(s, ".") 
    If pos = 0 Then 
     FileExtOf = "" 
    Else 
     FileExtOf = Mid$(s, pos + 1) 
    End If 
End Function 

Public Function FileNameExtOf(ByVal s As String) As String 
    FileNameExtOf = Mid$(s, InStrRev(s, "\") + 1) 
End Function 

Answer 2

爲什麼重新發明輪子並寫下大量的樣板代碼？只需使用現有FileSystemObject的用GetFileName方法，已經編寫和測試和調試你：

filename = FSO.GetFileName(path) 

這裏有一個工作示例：

Dim path As String 
Dim filename As String 
Dim FSO As Scripting.FileSystemObject 
Set FSO = New FileSystemObject 

path = "C:\mydir\myotherdir\myfile.txt" 

filename = FSO.GetFileName(path) 'Bingo. Done. 

Debug.Print filename ' returns "myfile.txt" 

' Other features: 
Debug.Print FSO.GetBaseName(path) ' myfile 
Debug.Print FSO.GetExtensionName(path) ' txt 
Debug.Print FSO.GetParentFolderName(path) ' C:\mydir\myotherdir 
Debug.Print FSO.GetDriveName(path) ' C: 
' et cetera, et cetera. 

您將需要設置一個參考如下： 工具> References ...>在Microsoft Scripting Runtime旁邊設置複選標記。

否則使用後期綁定：

Dim FSO As Object 
Set FSO = CreateObject("Scripting.FileSystemObject") 

Answer 3

激活有問題的文件，然後：

Function getname() 

arr = Split(ActiveDocument.FullName, "\") 
Debug.Print arr(UBound(arr)) 

End Function 

我假設你使用Word，因而有 「的ActiveDocument」。在適當情況下將其更改爲「ActiveWorksheet」等

Answer 4

'更簡單永遠是更好的！ （替代適用小區位置R1C1路徑和字符串長度）

Dim TheFile As String 
Dim TheFileLessPath As String 

Function getname() 
Workbooks.Open filename:=TheFile 
TheFileLessPath = Mid(TheFile, 12, 7) 

ActiveCell.FormulaR1C1 = TheFileLessPath 
End Function 

Answer 5

在這種情況下，您正在使用Application.GetOpenFilename（），所以你一定該文件在磁盤上的物理存在，所以最簡單的方法將是使用Dir（）。

fileName = Dir(filePath) 

的完整代碼：

Dim fileName, filePath As Variant 

filePath = Application.GetOpenFilename("Excel files (*.xlsm), *.xlsm", , "Select desired file", , False) 

If filePath = False Then 
    MsgBox "No file selected.", vbExclamation, "Sorry!" 
    Exit Sub 
Else 

    'Remove path from full filename 
    fileName = Dir(filePath) 

    'Print file name (with extension) 
    MsgBox "File selected." & vbCr & vbCr & fileName, vbInformation, "Sucess!" 

End If