德爾福管理的可用內存

Question

形勢

我從馬可·坎的書學習Delphi和我已經有經驗的面向對象，因爲我通常使用Java和PHP工作。爲了更好地理解我在讀什麼，我做了這個測試：

type 
TFraction = class 
    private 
    number: double; 
    num, den: integer; 
    fraction: string; 
    function hcf(x: integer; y: integer): integer; 
    public 
    constructor Create(numerator: integer; denominator: integer); overload; 
    constructor Create(value: string); overload; 
    function getFraction: string; 
end; 

這是一個超級簡單的類，它的十進制數轉換成分數。我沒有包含代碼中用於定義構造函數和函數的其他部分，因爲它們對我的問題沒有用處。我以這種方式創建對象。

var a: TFraction; 
begin 

a := TFraction.Create(225, 35); 
ShowMessage(a.getFraction); 
//The output of^is 45/7 
a.Free; 

end; 

---

問題

據我瞭解，我知道我必須擺脫的對象，一旦我使用它，其實我現在用的是Free。通過這種方式，我釋放了內存，避免了內存泄漏。

順便說一句，我看到我也有可能重寫destructor。我不太瞭解Free和Destroy的行爲。當我不得不擺脫我不再需要的物體時，我使用Free。當我重寫一個析構函數時，我可以釋放該對象並進行其他操作？

總之，什麼時候使用Free？我應該什麼時候更喜歡Destroy？

Answer 1

通常，如果您需要在對象銷燬期間執行某些操作，則會使用析構函數，否則這些操作不會自動完成。就像釋放你在構造函數中初始化的內存一樣。在你的例子中，沒有必要重寫析構函數，因爲（大概）你不會創建任何需要手動銷燬的東西。

另外，請記住，Destroy不打算由您根本打電話 - 無論是內部還是外部。 Free會自動爲你打電話 - 只需要做一些額外的工作。 Free檢查對象是否爲nil，如果不是nil，則只調用Destroy。

藉此例如：

type 
    TMyObject = class(TObject) 
    private 
    FSomeOtherObject: TSomeOtherObject; 
    public 
    constructor Create; 
    destructor Destroy; override; 
    end; 

constructor TMyObject.Create; 
begin 
    inherited; 
    FSomeOtherObject:= TSomeOtherObject.Create; 
end; 

destructor TMyObject.Destroy; 
begin 
    FSomeOtherObject.Free; 
    inherited; 
end; 

只是作爲一個補充說明，我在上面看到的用法是失去了一些東西。如果Create和Free之間的代碼引發一些異常，該怎麼辦？程序將退出，並且永遠不會被釋放。因此，相反，你應該使用try/finally塊...

a := TFraction.Create(225, 35); 
try 
    ShowMessage(a.getFraction); 
finally 
    a.Free; 
end; 

這將確保無論try和finally之間發生了什麼，finally和end之間的代碼將總是被調用。

Answer 2

順便說一句，我看到我也有可能重寫destructor。我不太瞭解Free和Destroy的行爲。

Free()如果對象指針不爲零，則調用析構函數。

Destroy()是實際的析構函數。

我使用Free當我必須擺脫我不再需要的對象時。當我重寫一個析構函數時，我可以釋放該對象並進行其他操作？

是的。當對象處於被銷燬的過程中時，調用析構函數。覆蓋析構函數是執行與正在銷燬的對象相關的清理操作的好地方。

總之，什麼時候使用Free？我應該什麼時候更喜歡Destroy？

您可以呼叫Destroy()直接，但一般最好是打電話Free()，而不是讓它叫Destroy()你。