VB.NET：檢查列表項是否相等並具有相同的數

Question

如何檢測兩個給定列表的項是否相等？

Dim list1 As New List(Of Integer) 
list1.AddRange({1, 2, 3}) 

Dim list2 As New List(Of Integer) 
list2.AddRange({3, 2, 1}) 

如果我使用他們比較SequenceEqual，我得到False，因爲項目的順序是不一樣的。我怎麼能比較他們沒有排序他們第一，雖然？

編輯：請注意，這應該尊重重複，例如{1, 2, 3, 1}是不相同的{1, 2, 3}（項目1在第一個列表中發生兩次）。

Answer 1

<System.Runtime.CompilerServices.Extension()> _ 
Function AreItemsEqual(Of T)(col1 As IEnumerable(Of T), col2 As IEnumerable(Of T)) As Boolean 
    ' performance checks 
    If col1 Is col2 Then Return True 
    If col1 Is Nothing OrElse col2 Is Nothing Then Return False 
    If col1.Count <> col2.Count Then Return False 
    ' compare their elements 
    Dim o1 As IEnumerable(Of T) = col1.OrderBy(Function(i) i) 
    Dim o2 As IEnumerable(Of T) = col2.OrderBy(Function(i) i) 
    Return o1.SequenceEqual(o2) 
End Function 

用法：

If list1.AreItemsEqual(list2) Then 
    ... 

Answer 2

如果你想知道，如果兩個列表包含相同的項目，你可以使用Enumerable.Except：

Dim bothContainSameItems As Boolean 
If list1.Count > list2.Count Then 
    bothContainSameItems = Not list1.Except(list2).Any() 
Else 
    bothContainSameItems = Not list2.Except(list1).Any() 
End If 

，或者與HashSet(Of T)幫助：

Dim l1Set = New HashSet(Of Integer)(list1) 
Dim l2Set = New HashSet(Of Integer)(list2) 
bothContainSameItems = l1Set.SetEquals(l2Set) 

注意，這兩種方法會忽略重複。因此，他們將返回equal爲：

list1.AddRange({1, 1, 2, 3}) 
list2.AddRange({3, 2, 1, 3}) 

這裏是一個可能的方式也檢查所有數字有兩個列表相同的計數：

bothContainSameItems = list1.Count = list2.Count 
If bothContainSameItems Then 
    Dim l1Ordered = list1.OrderBy(Function(i) i).ToList() 
    Dim l2Ordered = list2.OrderBy(Function(i) i).ToList() 
    For i As Int32 = 0 To l1Ordered.Count - 1 
     If l1Ordered(i) <> l2Ordered(i) Then 
      bothContainSameItems = False 
      Exit For 
     End If 
    Next 
End If 

Answer 3

還與

Dim list1 As New List(Of Integer) 
list1.AddRange({1, 2, 3}) 

Dim list2 As New List(Of Integer) 
list2.AddRange({3, 2, 1}) 

Dim list3 = list1.Union(list2) 
if list3.OrderBy(Function(i) i).SequenceEqual(list1.OrderBy(Function(i) i)) then 
    Console.WriteLine("Equal") 
else 
    Console.WriteLine("Not Equal") 
end if 

IEnumerable.Union工作

返回值：包含來自兩個輸入序列的元素的IEnumerable（Of T）， 不包含重複項。