帶有替換的Perl過濾器

Question

我正在嘗試創建一個Perl腳本，用於過濾STDIN上顯示的數據，將所有出現的 一個字符串更改爲另一個字符串，並輸出所有輸入行，並將其更改並保留爲STDOUT。 FROMSTRING和TOSTRING可以是PERL兼容的正則表達式。我無法獲得匹配的輸出。

這裏是什麼，我想實現的例子。

echo "Today is Saturday" | f.pl 'a' '@' 

輸出Tod@y is S@turd@y。

echo io | filter.pl '([aeiou])([aeiou])' '$2$1' 

輸出oi。發現

#!/usr/bin/perl 
use strict; 
use warnings; 
if (@ARGV != 2){ 
     print STDERR "Usage: ./filter.pl FROMSTRING TOSTRING\n" 
} 
exit 1; 
my $FROM = $ARGV[0]; 
my $TO = $ARGV[1]; 
my $inLine = ""; 
while (<STDIN>){ 
$inLine = $_; 
$inLine =~ s/$FROM/$TO/; 
print $inLine 
} 
exit 0; 

Answer 1

三個錯誤：

; after error message 
exit 1; 
$inLine =~ s/$FROM/$TO/g; 

像：

#!/usr/bin/perl 
use strict; 
use warnings; 
if (@ARGV != 2){ 
     print STDERR "Usage: ./filter.pl FROMSTRING TOSTRING\n"; 
     exit 1; 
} 
my $FROM = $ARGV[0]; 
my $TO = $ARGV[1]; 
my $inLine = ""; 
while (<STDIN>){ 
$inLine = $_; 
$inLine =~ s/$FROM/$TO/g; 
print $inLine 
} 
exit 0; 

Answer 2

首先，一個操作s/.../.../的替換部分不是正則表達式;它像雙引號字符串一樣工作。

有幾個與你的代碼的問題。

• 你exit 1;語句出現在主代碼的中間，而不是在錯誤塊。你可能想：

  if (@ARGV != 2) { 
      print STDERR "Usage: ./filter.pl FROMSTRING TOSTRING\n"; 
      exit 1; 
  } 
  

• 你錯過，如果你想多換人在同一行發生一g標誌：

  $inLine =~ s/$FROM/$TO/g; 
  

• 有沒有必要預先聲明$inLine;它只在一個塊中使用。

• 但也沒有必要讀行成$_只是將其複製到$inLine。
• 它通常使用$names_like_this變量和函數，而不是$namesLikeThis。
• 可以使用$0，而不是在錯誤信息硬編碼的程序名。
• exit 0;是在端冗餘。

以下是更接近我怎麼會寫：

#!/usr/bin/perl 
use strict; 
use warnings; 

if (@ARGV != 2) { 
    die "Usage: $0 FROMSTRING TOSTRING\n"; 
} 

my ($from, $to) = @ARGV; 

while (my $line = readline STDIN) { 
    $line =~ s/$from/$to/g; 
    print $line; 
} 

---

這就是說，這些都不滿足您與'$2$1'作爲替換第二個例子。上面的代碼不會做你想要的，因爲$to是一個純字符串。 Perl不會掃描它來尋找類似$1的東西並替換它們。

當您在代碼中編寫"foo $bar baz"時，它與'foo ' . $bar . ' baz'意思相同，但這僅適用於代碼，即東西，字面上出現在您的源代碼。在運行時不會重新掃描$bar的內容以擴展例如\n或$quux。這也適用於$1和朋友，這只是普通變量。

那麼你如何得到'$2$1'工作？

一種方法是混淆eval，但我不喜歡它，因爲它是eval：如果你不是很小心，它會允許某人通過傳遞正確的替換字符串來執行任意代碼「string 」。

不用eval就可以做到這一點，甚至可以使用例如Data::Munge::replace：

#!/usr/bin/perl 
use strict; 
use warnings; 
use Data::Munge qw(replace); 

if (@ARGV != 2) { 
    die "Usage: $0 FROMSTRING TOSTRING\n"; 
} 

my ($from, $to) = @ARGV; 

while (my $line = readline STDIN) { 
    print replace($line, $from, $to, 'g'); 
} 

replace作品像JavaScript的String#replace，從而擴展特殊$序列。

做手工也是可能的，但有點惱人，因爲你基本上要像對待$to爲模板，擴大手工所有$序列（通過其他正則表達式替換EG）：

# untested 
$line =~ s{$from}{ 
    my @start = @-; 
    my @stop = @+; 
    (my $r = $to) =~ s{\$([0-9]+|\$)}{ 
     $1 eq '$' 
      ? '$' 
      : substr($from, $start[$1], $stop[$1] - $start[$1]) 
    }eg; 
    $r 
}eg; 

（這確實沒有實現如${1}，${2}等。這些都是作爲練習留給讀者桁組）。

此代碼是足夠煩人寫（看看），我更喜歡使用一個模塊一樣Data::Munge的日是某種事情。