這兩個組合器在Haskell中已經可用嗎？

Question

我需要的那種類型的二元組合子

(a -> Bool) -> (a -> Bool) -> a -> Bool 

也許

[a -> Bool] -> a -> Bool 

（雖然這也只是第一的foldr1，我通常只需要合併兩個布爾函數）。

這些是內置的嗎？

---

如果不是，實現簡單：

both f g x = f x && g x 
either f g x = f x || g x 

或許

allF fs x = foldr (\ f b -> b && f x) True fs 
anyF fs x = foldr (\ f b -> b || f x) False fs 

Hoogle變成了什麼，但有時其搜索無法正常一概而論。任何想法，如果這些是內置的？它們是否可以從現有的圖書館中創建？

如果這些不是內置的，您可能會建議新名稱，因爲這些名稱非常糟糕。其實這是我希望他們內置的的主要原因。

Answer 1

Control.Monad定義instance Monad ((->) r)，所以

 
ghci> :m Control.Monad 
ghci> :t liftM2 (&&) 
liftM2 (&&) :: (Monad m) => m Bool -> m Bool -> m Bool 
ghci> liftM2 (&&) (5 <) (< 10) 8 
True 

你可以做同樣的Control.Applicative.liftA2。

---

不認真建議，但是...

 
ghci> :t (. flip ($)) . flip all 
(. flip ($)) . flip all :: [a -> Bool] -> a -> Bool 
ghci> :t (. flip ($)) . flip any 
(. flip ($)) . flip any :: [a -> Bool] -> a -> Bool 

Answer 2

我不知道builtins，但我喜歡你提出的名字。

getCoolNumbers = filter $ either even (< 42) 

或者，人們可能覺得除了操作符號類型類的替代品。

getCoolNumbers = filter $ even <|> (< 42) 

Answer 3

這不是一個內置的，但我更喜歡另一種方法是使用類型類概括 布爾操作的任何謂詞元數：

module Pred2 where 

class Predicate a where 
    complement :: a -> a 
    disjoin :: a -> a -> a 
    conjoin :: a -> a -> a 

instance Predicate Bool where 
    complement = not 
    disjoin = (||) 
    conjoin = (&&) 

instance (Predicate b) => Predicate (a -> b) where 
    complement = (complement .) 
    disjoin f g x = f x `disjoin` g x 
    conjoin f g x = f x `conjoin` g x 


-- examples: 

ge :: Ord a => a -> a -> Bool 
ge = complement (<) 

pos = (>0) 
nonzero = pos `disjoin` (pos . negate) 
zero = complement pos `conjoin` complement (pos . negate) 

我喜歡哈斯克爾！